Penyiraman tumbuhan IoT dengan ESP32 (sensor tanah + pam)
Biarkan pam bermula sendiri apabila tanah dalam pasumu kering, dan pantau kelembapan tanah secara langsung di telefonmu. Projek ini ialah panduan langkah demi langkah bagi templat IoT Kelembapan tanah + pam dalam aplikasi, dibina dengan ESP32, sensor kelembapan tanah, geganti dan pam air mini. Pergi ke Bengkelku › Peranti › Tambah peranti; Ohmi menyediakan kod dengan kunci perantimu sendiri. Kod di halaman ini ialah contoh: kunci dan butiran Wi-Fi ialah nilai pemegang tempat.

Kawal peranti ini daripada aplikasi
Sambungkan ESP32 atau Raspberry Pi Pico W ke Wi-Fi, kemudian hidupkan dan matikan serta lihat bacaan secara langsung dari telefonmu. Ohmi menyediakan kod; kamu hanya perlu memasukkan maklumat Wi-Fi dan memuat naiknya.
Templat dalam aplikasi: Kelembapan tanah + pam
- Di mana dalam aplikasi?Tambah peranti baharu daripada tab Alatan atau Bengkelku › Peranti dan pilih templat ini.
- Pustaka ArduinoBuka Library Manager dalam Arduino IDE, cari BlueGraysIoT dan pasangnya.
Pelan percuma termasuk 1 peranti, 1 carta dan sejarah 24 jam. Premium menambah lebih banyak peranti, carta dan sejarah yang lebih panjang.
Video
Gambar Rajah Litar

Kod Sumber
1// ─────────────────────────────────────────
2// BlueGrays · bluegrays.com
3// ESP32 IoT Plant Watering (Soil Sensor + Pump)
4// ─────────────────────────────────────────
5// The "Soil moisture + pump" IoT template from the BlueGrays app: the soil
6// moisture sensor measures every 2 seconds and sends the value to the app,
7// the relay starts the pump when the moisture drops below the watering
8// threshold and stops it 10 points above it; you can also control the pump
9// and the threshold from your phone. Ohmi prepares the real code in the
10// app with your own device key (Workshop › Devices › Add a device); the
11// code here is an example, the device key and Wi-Fi details are
12// placeholders. Library Manager: BlueGraysIoT (with its dependencies). The
13// board only joins 2.4 GHz Wi-Fi networks. The relay switches on LOW.
14// Safety: power the pump from its own battery holder (4 x AA), not from
15// the board; keep the board, relay and batteries away from water in a
16// closed box; never run the pump dry.
17//
18// Pins:
19// GPIO34 -> Soil moisture sensor AO
20// 3V3, GND -> Soil moisture sensor VCC, GND
21// GPIO26 -> Relay module IN
22// 5V, GND -> Relay module VCC, GND
23// Relay COM -> battery holder (+), NO -> pump (+), pump (-) -> battery holder (-); the pump
24// runs on its own 4 x AA
25// Pico W: moisture sensor AO GP26, relay IN GP15
26
27/*
28 * Soil moisture + pump · BlueGrays IoT
29 * BlueGrays · bluegrays.com
30 * Do not share this code: it contains your device key and Wi-Fi password.
31 */
32
33#include <BlueGraysIoT.h>
34
35const char *DEVICE_KEY = "YOUR_DEVICE_KEY";
36const char *WIFI_NAME = "YOUR_WIFI_NAME";
37const char *WIFI_PASSWORD = "YOUR_WIFI_PASSWORD";
38
39BlueGraysIoT bg(DEVICE_KEY);
40
41const int RELAY_PIN = 26;
42const bool RELAY_ACTIVE_LOW = true; // most relay modules switch on LOW
43void setRelay(bool on) {
44 if (RELAY_ACTIVE_LOW) {
45 if (on) { pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, LOW); }
46 else { pinMode(RELAY_PIN, INPUT); } // off releases the pin: a 3.3 V HIGH is not enough to turn a 5 V module off
47 } else {
48 pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, on ? HIGH : LOW);
49 }
50}
51const int SOIL_PIN = 34;
52const int SOIL_DRY = 3200; // reading in dry soil
53const int SOIL_WET = 1300; // reading in wet soil
54int threshold = 30; bool pump = false; unsigned long lastReadMs = 0;
55
56void setup() {
57 Serial.begin(115200);
58 setRelay(false);
59 analogReadResolution(12);
60 bg.onSwitch("pompa", [](bool on) { pump = on; setRelay(on); });
61 bg.onNumber("esik", [](float v) { threshold = (int)v; });
62 bg.setDeadband("toprak", 1.0);
63 bg.setDebug(Serial);
64 bg.setLanguage(BG_LANG_EN);
65 bg.begin(WIFI_NAME, WIFI_PASSWORD);
66}
67
68void loop() {
69 bg.loop(); // avoid long delay() calls here
70 if (millis() - lastReadMs >= 2000) {
71 lastReadMs = millis();
72 int pct = constrain(map(analogRead(SOIL_PIN), SOIL_DRY, SOIL_WET, 0, 100), 0, 100);
73 bg.send("toprak", pct);
74 // Turn the pump on below the threshold, off 10 points above it
75 if (pct < threshold && !pump) { pump = true; setRelay(true); bg.send("pompa", true); }
76 if (pct > threshold + 10 && pump) { pump = false; setRelay(false); bg.send("pompa", false); }
77 }
78}
79Soalan Lazim
Bolehkah saya memuat naik kod di halaman ini terus ke papan saya?
Boleh, tetapi ia tidak akan bersambung: kunci peranti dan butiran Wi-Fi di dalamnya hanyalah nilai pemegang tempat. Dalam aplikasi, pergi ke Bengkelku › Peranti › Tambah peranti dan pilih templat Kelembapan tanah + pam; Ohmi menyediakan kod dengan kuncimu serta nama dan kata laluan Wi-Fi kamu. Salin kod itu dan muat naiknya. Kamu boleh melihat kod penuh kemudian dalam Peranti › Kod dan kunci.
Adakah ia berfungsi dengan Pico W?
Ya. Pilih Pico W sebagai papan semasa menambah peranti; kodnya kekal sama dan hanya pin serta nilai penentukuran yang berubah: sensor kelembapan ke GP26 (input analog) dan geganti ke GP15. Dalam Arduino IDE, pasang pakej "pico" daripada Boards Manager. Litar dan foto di halaman ini dibuat dengan ESP32.
Mengapakah pam mempunyai baterinya sendiri?
Arus yang ditarik oleh pam dan hingar daripada motornya boleh menetapkan semula papan. Itulah sebabnya pam berjalan daripada pemegang bateri 4 x AA dan hanya melalui terminal COM dan NO geganti; ia tiada sambungan wayar ke papan. Letakkan papan, geganti dan pemegang bateri jauh daripada air dalam kotak tertutup, dan pastikan sambungan wayar kering. Pam mesti berjalan di dalam air sahaja; jika berjalan kering, ia menjadi panas dan rosak dalam beberapa minit. Keluarkan bateri semasa kamu memasang hos atau mengangkat pam keluar dari air.
Bilakah pam berjalan, dan apakah yang berlaku jika saya mensuisnya secara manual?
Papan mengukur kelembapan setiap 2 saat. Apabila ia jatuh di bawah Ambang penyiraman dalam aplikasi (30% pada mulanya), pam dihidupkan, dan ia dimatikan 10 mata di atas ambang; jurang ini menghalang pam daripada berulang kali hidup dan mati. Kamu juga boleh mengetik suis Pam secara manual, tetapi peraturan automatik mengatasinya: jika kamu mematikannya semasa tanah di bawah ambang, ia hidup semula dalam 2 saat, dan jika kamu menghidupkannya semasa tanah 10 mata di atas ambang, ia terus dimatikan. Tetapkan ambang mengikut pasumu.
