Komponen · 9 mnt baca

Panduan TFT LCD shield 2,4 inci Arduino: MCUFRIEND_kbv, sentuh, dan SD

TFT LCD shield 2,4 inci di Arduino: instalasi MCUFRIEND_kbv, membaca ID driver, mengatasi layar putih, kalibrasi sentuh, tombol, gambar BMP dari SD, dan pin.

TFT LCD shield 2,4 inci untuk Arduino adalah layar sentuh berwarna 240×320 piksel yang langsung menancap di atas Arduino Uno. Tanpa kabel, tanpa solder: kamu mendudukkan shield di header Uno atau Mega, memasang library yang tepat, dan dalam hitungan menit sudah menampilkan teks berwarna, bentuk, tombol sentuh, dan gambar dari kartu SD. Harganya murah, jadi ia muncul di banyak sekali starter kit dan proyek sekolah; karena alasan yang sama, ia termasuk komponen yang paling sering ditanyakan orang di internet dengan pertanyaan “kenapa layarku cuma putih?”.

Di panduan ini kamu akan melihat kenapa shield ini kadang menampilkan layar putih dan bagaimana library MCUFRIEND_kbv mengatasinya. Kamu akan mencari ID driver, mengalibrasi panel sentuh, memperbaiki sentuhan yang terbalik, mengendalikan LED dengan tombol di layar, dan menampilkan gambar dari kartu microSD. Kami juga membahas pin mana yang dipakai shield, pin mana yang tersisa, dan apa yang perlu diperhatikan di Mega, ESP32, dan Pico.

Board Arduino Uno
TFT shield 2,4 inci duduk di atas board ini dan memakai hampir semua pinnya; yang tersisa hanya A5, D0–D1 dan, kalau kartu SD tidak dipakai, D10–D13.

Apa itu TFT shield 2,4 inci dan bagaimana cara kerjanya?

Shield ini punya tiga bagian: panel TFT berwarna, lapisan sentuh resistif yang ditempel di atasnya, dan slot kartu microSD di bagian belakang. Layarnya tidak terhubung lewat bus serial seperti SPI, melainkan lewat bus paralel 8 bit; karena mengirim satu byte utuh sekaligus, ia menggambar lebih cepat di Uno dibanding modul SPI, tetapi memakai banyak pin. Chip driver panelnya bekerja pada 3,3 V; berkat regulator 3,3 V dan level shifter sejenis 74HC245 di board-nya, sinyal 5 V dari Uno aman dipakai.

FiturNilai
LayarTFT 2,4 inci, 240×320 piksel
Warna16 bit (RGB565), 65.536 warna
AntarmukaParalel 8 bit (D0–D7) + 5 jalur kontrol
Chip driverBervariasi: ILI9341, ILI9325, ST7781, SPFD5408, HX8347, dan lainnya
SentuhResistif 4 kawat, berbagi pin dengan layar
Slot SDmicroSD lewat SPI (D10–D13)
Catu daya5 V (regulator 3,3 V di board)
ArusSekitar 80–120 mA, sebagian besar untuk lampu latar
Board yang kompatibelArduino Uno, Arduino Mega 2560

Shield atau modul SPI?

Ada dua produk berbeda dengan ukuran sama yang dijual, dan keduanya sama-sama disebut “TFT 2,4 inci”. Shield adalah model paralel yang tinggal kamu tancapkan ke Uno dan langsung jalan. Modul SPI punya satu baris pin header di salah satu sisinya dan disambungkan dengan kabel jumper; panel sentuhnya biasanya dibaca lewat SPI dengan chip XPT2046. Panduan ini membahas shield; untuk modul SPI, lihat panduan layar TFT ILI9341 kami.

Modul layar TFT ILI9341 dengan antarmuka SPI
Saudara si shield: modul SPI disambungkan dengan kabel jumper lewat satu baris pin header dan jauh lebih cocok untuk ESP32 dan Pico.
FiturShield Uno 2,4 inciModul SPI 2,4 inci
KoneksiMenancap di Uno atau Mega, tanpa kabel7 sampai 14 kabel jumper
Pin yang dipakaiD2–D9, A0–A4 (D10–D13 dengan SD)5 untuk layar, 8–9 dengan sentuh dan SD
Kecepatan menggambar di UnoCepat (paralel)Lebih lambat (SPI)
LibraryMCUFRIEND_kbvAdafruit_ILI9341, TFT_eSPI
Pembacaan sentuhAnalog, pinnya berbagi dengan layarChip XPT2046 lewat SPI
ESP32 dan PicoTidak cocokCocok
Pin cadangan untuk sensorHampir tidak adaBanyak

Tabel pin: pin mana saja yang dipakai shield?

Pin shieldPin Arduino UnoFungsi
LCD_RDA0Strobe baca
LCD_WRA1Strobe tulis (bisa berbagi dengan sentuh)
LCD_RS (CD)A2Perintah atau data? (berbagi dengan sentuh)
LCD_CSA3Chip select layar (bisa berbagi dengan sentuh)
LCD_RSTA4Reset layar
LCD_D0, LCD_D1D8, D9Dua bit pertama bus data
LCD_D2–LCD_D7D2–D7Enam bit sisanya dari bus data
SD_SS / SD_DI / SD_DO / SD_SCKD10 / D11 / D12 / D13Kartu microSD (SPI)
5V, 3V3, GND5V, 3.3V, GNDDaya
Dengan shield terpasang, Uno nyaris tidak punya pin tersisa untuk sensor. Karena A4 menjadi jalur reset layar, bus I2C di A4/A5 tidak bisa dipakai, jadi kamu tidak bisa menambahkan sensor atau layar I2C. Yang tersisa: A5 (tidak terhubung di kebanyakan shield), D0–D1 yang dipakai bersama untuk upload lewat USB, dan D10–D13 kalau kamu tidak memakai kartu SD. Kalau butuh lebih banyak sensor, pasang shield di Arduino Mega atau beralihlah ke modul SPI.

Memasang library MCUFRIEND_kbv

  1. Buka Library Manager di Arduino IDE, cari MCUFRIEND_kbv, lalu instal.
  2. Dari tempat yang sama, instal Adafruit GFX Library; fungsi teks, garis, lingkaran, dan tombol berasal dari sana.
  3. Untuk sentuh, instal library Adafruit TouchScreen (di kode disertakan sebagai TouchScreen.h).
  4. Untuk kartu SD kamu tidak perlu memasang apa-apa; library SD sudah bawaan Arduino IDE.

Kenapa MCUFRIEND_kbv? Shield-shield ini bisa tampak identik tetapi berisi chip driver yang berbeda: dua shield yang dibeli dari penjual yang sama dengan selang dua bulan bisa saja ternyata ILI9341 dan ST7781. Library lama seperti Adafruit_TFTLCD atau SPFD5408 hanya mengenal beberapa chip; kalau chipnya tidak cocok, layar tidak pernah diinisialisasi dan kamu mendapat layar putih yang terkenal itu. MCUFRIEND_kbv lebih dulu menanyakan ID ke chip, lalu mengirim perintah inisialisasi yang sesuai dengan chip tersebut.

Mencari ID driver: readID()

Tugas pertama adalah menanyakan identitas shield-mu. Kode di bawah mencetak ID ke Serial Monitor dan ke layar, lalu menggambar tiga kotak berwarna. Atur Serial Monitor ke 9600 baud.

C++ (Arduino IDE)
1#include <Adafruit_GFX.h>
2#include <MCUFRIEND_kbv.h>
3
4MCUFRIEND_kbv tft;
5
6void setup() {
7  Serial.begin(9600);
8  uint16_t id = tft.readID();                 // sürücü kimliğini oku / read the driver ID
9  Serial.print(F("TFT ID = 0x"));
10  Serial.println(id, HEX);
11  if (id == 0xD3D3) id = 0x9341;              // salt yazılır shield: kimliği elle ver / write-only shield: set the ID by hand
12  tft.begin(id);
13  tft.setRotation(1);                         // yatay, 320x240 / landscape, 320x240
14  tft.fillScreen(0x0000);                     // siyah / black
15  tft.setTextColor(0xFFFF);                   // beyaz / white
16  tft.setTextSize(3);
17  tft.setCursor(20, 20);
18  tft.print(F("BlueGrays"));
19  tft.setTextSize(2);
20  tft.setCursor(20, 70);
21  tft.print(F("ID: 0x"));
22  tft.print(id, HEX);
23  tft.fillRect(20, 120, 80, 60, 0xF800);      // kırmızı / red
24  tft.fillRect(120, 120, 80, 60, 0x07E0);     // yeşil / green
25  tft.fillRect(220, 120, 80, 60, 0x001F);     // mavi / blue
26}
27
28void loop() {
29}
ID yang terbacaChipYang perlu dilakukan
0x9341ILI9341Model paling umum; langsung jalan
0x9325 / 0x9328ILI9325 / ILI9328Lebih lama tetapi andal; langsung jalan
0x7783ST7781Langsung jalan
0x5408SPFD5408Langsung jalan; tidak perlu library SPFD5408 yang lama
0x4747 / 0x9595HX8347-D / HX8347-ILangsung jalan
0x1505 / 0x0154R61505 / S6D0154Langsung jalan
0xD3D3Shield tanpa jalur baca yang terhubungTulis ID-nya ke kode secara manual; untuk 2,4 inci coba 0x9341 dulu
0x0000 atau 0xFFFFTidak ada responsShield belum duduk sempurna, ada pin bengkok, atau board rusak

Kalau kotak-kotaknya muncul merah, hijau, dan biru dengan urutan itu, semuanya beres. Kalau yang terlihat biru, bukan merah, kemungkinan kamu mengisi ID secara manual sehingga perintah inisialisasi yang terkirim salah, jadi pakailah nilai yang ditemukan readID. Kalau warnanya tampak seperti negatif foto, tambahkan baris tft.invertDisplay(true) setelah begin. Kalau ID-nya aneh, contoh File > Examples > MCUFRIEND_kbv > LCD_ID_readreg dari library ini menampilkan semua register chip, dan keluaran itu adalah cara tercepat untuk memahami masalahnya. Contoh graphictest_kbv menguji semua fungsi layar sekaligus.

Layar putih dan masalah tampilan lainnya

Layar putih sebenarnya sebuah petunjuk: lampu latar mendapat daya, tetapi chip driver tidak pernah diinisialisasi. Ketika panel tidak menerima perintah, pikselnya meneruskan cahaya dan seluruh layar tampak putih. Telusuri tabel berikut dari atas ke bawah:

GejalaKemungkinan penyebabSolusi
Layar putih dengan library lamaLibrary tidak mengenal chip-muInstal MCUFRIEND_kbv dan mulai dengan readID
Layar putih, ID 0x0000 atau 0xFFFFShield belum duduk sempurna atau ada pin bengkokLepas shield, luruskan pinnya, lalu tekan sampai mentok
Layar putih, ID 0xD3D3Tidak ada jalur baca, jadi ID tidak bisa dibacaIsi ID secara manual, misalnya tft.begin(0x9341); kalau gagal, coba 0x9325 dan 0x7783
Warna negatif (putih tampak hitam)Pengaturan inversi chipnya berbedatft.invertDisplay(true) setelah begin
Merah dan biru tertukarID yang diisi manual tidak cocok dengan chipnyaPakai ID yang ditemukan readID dan perbarui library ke versi terbaru
Teks tercerminID yang diisi manual tidak cocok dengan panelnyaAmbil ID dengan readID; periksa keempat orientasi dengan contoh aspect_kbv
Gambar rusak begitu layar disentuhPembacaan sentuh meninggalkan pin bersama sebagai inputKembalikan YP dan XM ke OUTPUT setelah getPoint
Jalan di Uno, putih di MegaLibrary tidak mengenal pemetaan pin MegaMCUFRIEND_kbv mendukung Mega; hapus library lama

Mengalibrasi panel sentuh

Panel sentuh resistif terbuat dari dua lapisan resistif tipis dengan celah sangat kecil di antaranya. Begitu kamu menekan, kedua lapisan bersentuhan; library memberi tegangan pada satu lapisan dan membaca tegangan di lapisan lainnya dengan input analog, sehingga mendapat posisi X dan Y. Hasil bacaan itu berupa angka mentah, kira-kira 100 sampai 900, dan berbeda di tiap panel, jadi kamu perlu kalibrasi untuk mengubahnya menjadi piksel. Panel sentuh juga berbagi pin dengan layar, dan empat pin mana yang menuju lapisan sentuh berbeda dari satu shield ke shield lain.

  1. Buka contoh TouchScreen_Calibr_native dari File > Examples > MCUFRIEND_kbv lalu upload.
  2. Buka Serial Monitor pada 9600 baud; contoh ini lebih dulu mencari sendiri pin sentuhnya.
  3. Tekan tanda plus yang muncul di layar satu per satu, sambil menahan jari atau stylus di tiap tanda sampai teksnya berubah.
  4. Setelah selesai, dua baris muncul di bawah judul “COPY-PASTE” di Serial Monitor: const int XP=...,XM=...,YP=...,YM=... dan const int TS_LEFT=...,TS_RT=...,TS_TOP=...,TS_BOT=....
  5. Tempelkan kedua baris itu menggantikan nilai contoh di bagian atas sketch-sketch di bawah.
C++ (Arduino IDE)
1#include <Adafruit_GFX.h>
2#include <MCUFRIEND_kbv.h>
3#include <TouchScreen.h>
4
5MCUFRIEND_kbv tft;
6
7// Kalibrasyon örneğinin çıktısını buraya yapıştır / paste the calibration sketch output here
8const int XP = 6, XM = A2, YP = A1, YM = 7;
9const int TS_LEFT = 907, TS_RT = 136, TS_TOP = 942, TS_BOT = 139;
10
11TouchScreen ts = TouchScreen(XP, YP, XM, YM, 300);   // 300 ohm X plakası / 300 ohm X plate
12const int MINPRESSURE = 200;
13const int MAXPRESSURE = 1000;
14
15bool readTouch(int &x, int &y) {
16  TSPoint p = ts.getPoint();
17  pinMode(YP, OUTPUT);                 // ortak pinleri ekrana geri ver / give the shared pins back to the display
18  pinMode(XM, OUTPUT);
19  digitalWrite(YP, HIGH);
20  digitalWrite(XM, HIGH);
21  if (p.z < MINPRESSURE || p.z > MAXPRESSURE) return false;
22  x = map(p.x, TS_LEFT, TS_RT, 0, tft.width());    // dikey yön için / for portrait
23  y = map(p.y, TS_TOP, TS_BOT, 0, tft.height());
24  return true;
25}
26
27void setup() {
28  tft.begin(tft.readID());
29  tft.setRotation(0);                  // dikey, kalibrasyonla aynı / portrait, same as calibration
30  tft.fillScreen(0x0000);
31  tft.fillRect(0, 0, 240, 30, 0x001F);
32  tft.setTextColor(0xFFFF);
33  tft.setTextSize(2);
34  tft.setCursor(10, 8);
35  tft.print(F("Ciz / Draw"));
36}
37
38void loop() {
39  int x, y;
40  if (readTouch(x, y)) {
41    if (y < 30) tft.fillRect(0, 30, 240, 290, 0x0000);   // başlığa dokun: temizle / tap the header: clear
42    else tft.fillCircle(x, y, 3, 0xFFE0);                 // sarı nokta / yellow dot
43  }
44}

Program gambar kecil ini adalah cara terbaik untuk menguji kalibrasimu: titiknya harus jatuh hampir tepat di bawah jarimu. p.z adalah tekanannya; kalau nilainya tidak berada di antara MINPRESSURE dan MAXPRESSURE, itu tidak dihitung sebagai sentuhan, sehingga sapuan ringan dan noise listrik tersaring. Baris-baris pinMode di dalam readTouch() sangat penting: selagi membaca, library TouchScreen mengubah pin bersama menjadi input analog dan membiarkannya begitu; tanpa baris-baris ini, perintah gambar berikutnya tidak pernah sampai ke layar dan gambarnya rusak. Satu tips: panel resistif bekerja dengan tekanan, jadi kuku atau stylus menggambar lebih presisi daripada ujung jari.

GejalaPenyebabSolusi
Menyentuh sisi kanan memunculkan titik di kiriSumbu X terbalikTukar nilai TS_LEFT dan TS_RT
Menyentuh bagian atas memunculkan titik di bawahSumbu Y terbalikTukar nilai TS_TOP dan TS_BOT
X dan Y tertukar di mode lanskapsetRotation(1) memutar sumbunyaGunakan map pada p.y untuk x dan p.x untuk y, atau tetap di mode potret
Sentuhan sama sekali tidak terdeteksiXP, XM, YP, YM salahJalankan lagi contoh kalibrasi dan pakai pin yang dilaporkannya
Titik muncul tanpa disentuhAmbang tekanan terlalu rendahNaikkan MINPRESSURE ke 300–400
Titik meleset beberapa pikselKalibrasinya terburu-buruKalibrasi ulang, tekan tepat di tengah tiap tanda plus dengan lebih lama

Antarmuka tombol sentuh

Kelas Adafruit_GFX_Button di library Adafruit GFX menggambar tombol dengan garis tepi dan label hanya dalam beberapa baris, dan ia menghitung sendiri apakah sebuah sentuhan jatuh di tombol itu. Kode di bawah menyalakan dan mematikan LED di A5 dengan dua tombol; kami memilih A5 karena praktis itulah satu-satunya pin Uno yang tersisa dengan shield terpasang. Jangan lupa menyambungkan LED lewat resistor 220 Ω.

C++ (Arduino IDE)
1#include <Adafruit_GFX.h>
2#include <MCUFRIEND_kbv.h>
3#include <TouchScreen.h>
4
5MCUFRIEND_kbv tft;
6const int XP = 6, XM = A2, YP = A1, YM = 7;                       // kendi değerlerin / your own values
7const int TS_LEFT = 907, TS_RT = 136, TS_TOP = 942, TS_BOT = 139;
8TouchScreen ts = TouchScreen(XP, YP, XM, YM, 300);
9
10const int LED_PIN = A5;               // shield'in boş bıraktığı pin / the pin the shield leaves unused
11Adafruit_GFX_Button onBtn, offBtn;
12char onLabel[] = "ON";
13char offLabel[] = "OFF";
14
15bool readTouch(int &x, int &y) {
16  TSPoint p = ts.getPoint();
17  pinMode(YP, OUTPUT);
18  pinMode(XM, OUTPUT);
19  digitalWrite(YP, HIGH);
20  digitalWrite(XM, HIGH);
21  if (p.z < 200 || p.z > 1000) return false;
22  x = map(p.x, TS_LEFT, TS_RT, 0, tft.width());
23  y = map(p.y, TS_TOP, TS_BOT, 0, tft.height());
24  return true;
25}
26
27void showState(bool on) {
28  tft.fillRect(20, 40, 200, 60, on ? 0x07E0 : 0x7BEF);  // yeşil ya da gri / green or grey
29  tft.setTextColor(0x0000);
30  tft.setTextSize(3);
31  tft.setCursor(50, 58);
32  tft.print(on ? F("LED ON") : F("LED OFF"));
33}
34
35void setup() {
36  pinMode(LED_PIN, OUTPUT);
37  tft.begin(tft.readID());
38  tft.setRotation(0);
39  tft.fillScreen(0x0000);
40  // merkez x, merkez y, genişlik, yükseklik, çerçeve, dolgu, yazı rengi, etiket, yazı boyu
41  // center x, center y, width, height, outline, fill, text colour, label, text size
42  onBtn.initButton(&tft, 120, 170, 160, 60, 0xFFFF, 0x07E0, 0x0000, onLabel, 3);
43  offBtn.initButton(&tft, 120, 260, 160, 60, 0xFFFF, 0xF800, 0xFFFF, offLabel, 3);
44  onBtn.drawButton();
45  offBtn.drawButton();
46  showState(false);
47}
48
49void loop() {
50  int x = 0, y = 0;
51  bool down = readTouch(x, y);
52  onBtn.press(down && onBtn.contains(x, y));
53  offBtn.press(down && offBtn.contains(x, y));
54  if (onBtn.justPressed()) {
55    onBtn.drawButton(true);             // basılı görünüm / pressed look
56    digitalWrite(LED_PIN, HIGH);
57    showState(true);
58  }
59  if (offBtn.justPressed()) {
60    offBtn.drawButton(true);
61    digitalWrite(LED_PIN, LOW);
62    showState(false);
63  }
64  if (onBtn.justReleased()) onBtn.drawButton();
65  if (offBtn.justReleased()) offBtn.drawButton();
66  delay(20);
67}

press() mencatat di setiap putaran apakah tombol sedang ditekan pada momen itu; justPressed() mengembalikan true hanya pada putaran pertama tombol ditekan, dan justReleased() hanya pada putaran tombol dilepas. Dengan begitu LED tidak menerima perintah yang sama berulang-ulang selama jarimu masih di tombol, dan layar tidak digambar ulang dengan sia-sia. drawButton(true) membalik warna tombol untuk memberi kesan sedang ditekan. Sambungkan modul relay ke A5 sebagai ganti LED dan kamu bisa menyalakan dan mematikan lampu dari layar sentuh; untuk pengkabelan yang aman, lihat panduan modul relay kami.

Menampilkan gambar dari kartu SD

Slot microSD di bagian belakang adalah cara termudah untuk menampilkan gambar berwarna penuh di layar. Di komputer, ubah ukuran gambar menjadi 240×320 (potret) dan simpan sebagai BMP 24 bit: di Paint pilih “24-bit Bitmap”, di GIMP pilih opsi 24 bit ketika mengekspor. Batasi nama file paling banyak 8 karakter (misalnya KUCING.BMP), karena library SD bekerja dengan nama pendek, dan ganti “KEDI.BMP” di kode dengan nama filemu. Format kartunya sebagai FAT32 atau FAT16; kartu yang lebih besar dari 32 GB biasanya berformat exFAT dan tidak akan dikenali.

C++ (Arduino IDE)
1#include <SPI.h>
2#include <SD.h>
3#include <Adafruit_GFX.h>
4#include <MCUFRIEND_kbv.h>
5
6MCUFRIEND_kbv tft;
7const int SD_CS = 10;                 // shield üzerindeki SD seçme pini / SD chip select on the shield
8const byte CHUNK = 20;                // tek seferde okunan piksel / pixels read per step (az RAM / low RAM)
9
10uint16_t read16(File &f) { uint16_t v; f.read((uint8_t *)&v, 2); return v; }
11uint32_t read32(File &f) { uint32_t v; f.read((uint8_t *)&v, 4); return v; }
12
13bool drawBMP(const char *name, int x, int y) {
14  File bmp = SD.open(name);
15  if (!bmp) return false;
16  if (read16(bmp) != 0x4D42) { bmp.close(); return false; }   // "BM" imzası / "BM" signature
17  read32(bmp); read32(bmp);                                   // dosya boyutu, ayrılmış / file size, reserved
18  uint32_t offset = read32(bmp);                              // piksel verisinin başı / start of pixel data
19  read32(bmp);                                                // başlık boyutu / header size
20  int32_t w = read32(bmp);
21  int32_t h = read32(bmp);
22  if (read16(bmp) != 1 || read16(bmp) != 24 || read32(bmp) != 0) {  // 1 düzlem, 24 bit, sıkıştırmasız / 1 plane, 24-bit, uncompressed
23    bmp.close();
24    return false;
25  }
26  bool bottomUp = true;                                       // BMP satırları alttan üste / BMP rows are bottom-up
27  if (h < 0) { h = -h; bottomUp = false; }
28  uint32_t rowSize = (w * 3 + 3) & ~3UL;                      // satır 4 bayta tamamlanır / rows padded to 4 bytes
29  uint8_t raw[CHUNK * 3];
30  uint16_t px[CHUNK];
31  for (int32_t row = 0; row < h; row++) {
32    bmp.seek(offset + (bottomUp ? (h - 1 - row) : row) * rowSize);
33    tft.setAddrWindow(x, y + row, x + w - 1, y + row);        // tek satırlık pencere / one-row window
34    bool first = true;
35    for (int32_t col = 0; col < w; col += CHUNK) {
36      int n = (w - col < CHUNK) ? (w - col) : CHUNK;
37      bmp.read(raw, n * 3);
38      for (int i = 0; i < n; i++) {
39        px[i] = tft.color565(raw[i * 3 + 2], raw[i * 3 + 1], raw[i * 3]);   // BGR -> RGB565
40      }
41      tft.pushColors(px, n, first);
42      first = false;
43    }
44  }
45  tft.setAddrWindow(0, 0, tft.width() - 1, tft.height() - 1); // pencereyi sıfırla / reset the window
46  bmp.close();
47  return true;
48}
49
50void setup() {
51  Serial.begin(9600);
52  tft.begin(tft.readID());
53  tft.setRotation(0);                                         // dikey, 240x320 / portrait, 240x320
54  tft.fillScreen(0x0000);
55  if (!SD.begin(SD_CS)) {
56    Serial.println(F("SD kart yok / no SD card"));
57    return;
58  }
59  if (!drawBMP("KEDI.BMP", 0, 0)) {
60    Serial.println(F("BMP okunamadi / BMP not readable"));
61  }
62}
63
64void loop() {
65}

Di file BMP, baris-barisnya disimpan dari bawah ke atas dan tiap baris diberi byte pengisi hingga panjangnya kelipatan 4 byte; kode menangani kedua detail itu dengan perhitungan rowSize dan flag bottomUp. Tiap piksel memakan 3 byte dengan urutan biru, hijau, merah, dan color565() mengubahnya menjadi warna 16 bit yang dipahami layar. Karena Uno hanya punya RAM 2 KB dan library SD menyisihkan 512 byte di antaranya untuk buffer, kita membaca pikselnya 20 demi 20. Di Uno, gambar selayar penuh digambar baris demi baris dalam beberapa detik. Untuk format kartu dan penanganan file, lihat panduan modul kartu SD kami.

Memakainya dengan Arduino Mega

Shield ini pas di header Mega pada posisi yang sama, dan karena MCUFRIEND_kbv mengenali Mega, kode layar dan sentuh berjalan tanpa perubahan. Keuntungan besarnya ada di pin: D22–D53, A5–A15, tiga port serial tambahan, dan bus I2C di D20–D21 semuanya tersisa, sehingga Mega menjadi pilihan paling nyaman untuk proyek besar dengan sensor dan layar. Satu-satunya masalah adalah slot SD: shield menyambungkan kartu SD ke D10–D13, padahal SPI hardware Mega ada di D50–D53, sehingga SD.begin() gagal. Solusinya adalah memakai library SdFat dengan SPI software di D10–D13; contoh showBMP_not_Uno dari MCUFRIEND_kbv menunjukkan persis hal itu. Untuk semua pin Mega, lihat panduan pinout Arduino Mega kami.

Bisakah dipakai dengan ESP32 atau Raspberry Pi Pico?

Jawaban singkatnya: tidak disarankan. Shield paralel ini mengharapkan 13 pin dan header Uno yang ramah 5 V. Pada board ESP32 berbentuk Uno (ESPDuino-32, D1 R32, dan sejenisnya), pin header A2–A4 biasanya terhubung ke GPIO 34–36 yang hanya bisa menjadi input; jalur kontrol layar tidak bisa digerakkan dari sana, dan panel sentuh pun tidak menemukan pin yang cocok untuk pembacaan analognya. Ada yang berhasil menjalankannya dengan mengubah pengkabelan dan memakai pengaturan paralel TFT_eSPI, tetapi pekerjaannya merepotkan. Untuk ESP32 dan Pico, modul SPI dengan resolusi yang sama jauh lebih masuk akal: ia tersambung dengan empat atau lima kabel dan menyisakan sebagian besar pin. Detailnya ada di panduan layar TFT ILI9341 kami dan, untuk pilihan yang lebih kecil dan lebih tajam, panduan layar TFT ST7789.

Ide proyek TFT shield 2,4 inci

  • Kalkulator sentuh: gambar kisi tombol 4×4 dan tampilkan hasilnya dengan font besar; logikanya sama seperti di panduan kalkulator Arduino kami.
  • Bingkai foto digital: tampilkan file BMP di kartu SD secara bergiliran dan pindah ke gambar berikutnya begitu layar disentuh.
  • Kunci kode: gambar tombol angka di layar dan aktifkan relay di A5 begitu kode yang benar dimasukkan; untuk logika keypad-nya, lihat panduan keypad.
  • Game: Pong, Snake, atau tic-tac-toe sentuh; cari idenya di proyek game Arduino.
  • Grafik suhu: sambungkan DHT11 ke Mega dan tampilkan suhu satu jam terakhir sebagai grafik garis yang bergulir.
  • Osiloskop sederhana: gambar sinyal yang terbaca di A5 sebagai bentuk gelombang; untuk sinyal lambat, ini alat belajar yang seru.
Kalau layar berkedip, jangan hapus seluruh tampilan dengan fillScreen() di setiap putaran; bersihkan hanya area yang berubah dengan fillRect() lalu gambar ulang. Menaruh teks tetap di dalam F() menghemat RAM. Supaya latar di belakang angka yang berubah terhapus otomatis, pakai bentuk setTextColor(teks, latar).

Dengan library yang tepat, TFT shield 2,4 inci bisa hidup dalam hitungan menit, dan panel sentuhnya memberi proyekmu antarmuka pengguna yang sesungguhnya. Kalau kamu lebih suka mulai dengan layar yang lebih sederhana, aplikasi BlueGrays punya proyek langkah demi langkah lengkap dengan skema rangkaian dan kode untuk LCD I2C, teks berjalan di LCD 2x16, game Pong dan T-Rex di OLED, serta game lari di LCD.

Pertanyaan umum

Kenapa TFT shield 2,4 inci milikku menampilkan layar putih?

Layar putih berarti lampu latar menyala tetapi chip driver belum diinisialisasi. Penyebab paling umum adalah library-mu tidak mengenali chip di shield-mu. Memasang MCUFRIEND_kbv, membaca ID dengan tft.readID(), dan memulai layar dengan tft.begin(ID) hampir selalu menyelesaikannya; kalau ID yang kembali 0x0000, shield belum terpasang dengan benar.

Library apa yang sebaiknya dipakai untuk TFT shield 2,4 inci?

Pakai MCUFRIEND_kbv bersama Adafruit GFX Library untuk layar, Adafruit TouchScreen untuk sentuh, dan library SD bawaan Arduino IDE untuk kartunya. Library lama SPFD5408 dan Adafruit_TFTLCD hanya mendukung beberapa chip, itulah sebabnya keduanya biasanya menghasilkan layar putih di shield yang lebih baru.

Bagaimana cara mengetahui chip driver yang dipakai layar TFT-ku?

Panggil tft.readID() dengan MCUFRIEND_kbv dan cetak hasilnya ke Serial Monitor: 0x9341 berarti ILI9341, 0x9325 berarti ILI9325, dan 0x7783 berarti ST7781. Contoh LCD_ID_readreg dari library ini menampilkan semua register chip untuk detail lebih lanjut.

Apakah TFT shield 2,4 inci bisa dipakai dengan Arduino Mega?

Bisa, shield ini juga menancap di Mega dan MCUFRIEND_kbv mendukungnya. Hanya slot SD yang tidak langsung jalan, karena pin SPI Mega ada di D50–D53; untuk kartu SD kamu butuh library SdFat dengan SPI software. Sebagai gantinya, kamu mendapat banyak pin cadangan.

Bagaimana cara memperbaiki sentuhan terbalik pada TFT shield?

Pertama, jalankan lagi contoh TouchScreen_Calibr_native dan tempelkan nilai yang dicetaknya ke kodemu. Kalau kiri dan kanan tertukar, tukar TS_LEFT dan TS_RT; kalau atas dan bawah tertukar, tukar TS_TOP dan TS_BOT. Kalau sumbunya tertukar di mode lanskap, gunakan map pada p.y untuk x dan p.x untuk y.

Pin mana saja yang tersisa dengan TFT shield terpasang?

Di Uno hanya tersisa A5, D0–D1 (dipakai bersama untuk upload lewat USB) dan, kalau kartu SD tidak dipakai, D10–D13. Karena A4 menjadi jalur reset layar, I2C tidak bisa dipakai. Kalau ingin menyambungkan lebih banyak sensor, Arduino Mega atau modul TFT berantarmuka SPI lebih cocok.

Lihat semua proyek
Menggunakan Layar LCD dengan I2C
AR-32Pemula
Premium

Menggunakan Layar LCD dengan I2C

Beri Arduino-mu layar sendiri dan buat ia menulis pesan pertamanya. Layar LCD dua baris tersambung hanya dengan beberapa kabel; sapaan muncul di baris atas, lalu pesan kedua di baris bawah, layar…

4.8(53)
70
Menampilkan Pesan di Layar LCD 2x16
AR-29Mahir
Premium

Menampilkan Pesan di Layar LCD 2x16

Langkah pertamamu menulis teks di layar. Layar LCD dua baris pertama-tama menampilkan pesan tunggu, lalu menulis sapaan di baris atas dan mengetik sebuah kata huruf demi huruf di baris bawah seperti…

4.6(37)
51
Animasi Teks Memantul di LCD
AR-30Mahir
Premium

Animasi Teks Memantul di LCD

Di baris atas layar LCD, kata BLUEGRAYS meluncur dari satu tepi ke tepi lainnya lalu memantul kembali seperti bola yang mengenai dinding, terus tanpa henti.

4.5(29)
40
Game Bola Pemukul - SSD1306
AR-86Menengah
Premium

Game Bola Pemukul - SSD1306

Satu bola, dua pemukul, dan kamu: kamu bermain tenis meja, salah satu video game paling awal, di layar OLED kecil.

4.5(47)
65
OLED T-Rex Run: Game Dinosaurus Arduino
AR-87Mahir
Premium

OLED T-Rex Run: Game Dinosaurus Arduino

Game dinosaurus yang muncul ketika internetmu putus, sekarang ada di mejamu: dinosaurus berlari di layar OLED kecil, kaktus datang menghampiri, dan kamu melompat dengan satu tombol.

4.7(33)
53
Game Lari LCD Arduino
AR-96Menengah
Premium

Game Lari LCD Arduino

Game lari tanpa akhir yang bergulir ke samping di layar LCD karakter 16x2. Sang jagoan berlari otomatis, dan pemain melompati rintangan dengan menekan tombol. Rintangan acak muncul di baris atas dan bawah. Buzzer pasif memainkan melodi pembuka, suara lompat, suara perayaan 50 poin, dan melodi akhir game. Layar pembuka "BlueGrays - Arduino Projects" tampil ketika mulai. Skor langsung diperbarui di pojok kanan atas layar.

4.6(32)
56
Kalkulator I2C Arduino
AR-94Menengah
Premium

Kalkulator I2C Arduino

Proyek kalkulator berbasis Arduino yang melakukan penjumlahan, pengurangan, perkalian, dan pembagian memakai keypad membran 4x4 dan layar LCD I2C 16x2. Berkat I2C, sambungan layar hanya butuh 2 kabel, sehingga kabel tidak semrawut dan lebih banyak pin tetap bebas dipakai. Kalkulator ini juga mendukung input bilangan desimal dan bilangan negatif.

5.0(31)
43
Kunci Sandi dengan Keypad 4x4 dan LCD
AR-64Mahir
Premium

Kunci Sandi dengan Keypad 4x4 dan LCD

Kunci pintu elektronik kecil yang menahan siapa pun yang tidak tahu kodenya. Kamu menekan tombol pagar lalu mengetik kodenya di keypad; jika benar, layar menulis akses diberikan, LED hijau menyala…

4.8(59)
75