ESP32 Bluetooth Suhu dan Kelembapan (DHT11)
Pantau suhu dan kelembapan kamarmu secara langsung di ponsel dengan ESP32 dan sensor DHT11: dua kotak ukur dan grafik diperbarui setiap 2 detik, tanpa internet. Proyek ini adalah panduan langkah demi langkah untuk templat Bluetooth Suhu dan kelembapan di aplikasi. Buka Labku › Perangkat › Tambah perangkat › Bluetooth, pilih templatnya, lalu unggah kode lewat Ambil kodenya. Tombol Siapkan sebagai panel Bluetooth di halaman ini membuka wizard yang sudah siap.

Video
Skema rangkaian

Kode sumber
1// ┌───────────────────────────┐
2// │ BlueGrays · bluegrays.com │
3// │ Bluetooth · ESP32 │
4// │ BG-Hava │
5// └───────────────────────────┘
6// Suhu dan kelembapan
7// Board di Arduino IDE: ESP32 Dev Module
8// library BLE sudah ikut paket board ESP32, tidak perlu pasang apa-apa lagi
9
10#include <BLEDevice.h>
11#include <BLEServer.h>
12#include <BLE2902.h>
13#include <DHT.h> // Library Manager: 'DHT sensor library' (Adafruit)
14
15const char BLE_NAME[] = "BG-Hava"; // papan menyiarkan nama ini, aplikasi menemukannya di daftar dengan nama ini
16
17// Pin: ubah di sini kalau sambunganmu berbeda
18const int DHT_PIN = 4;
19const unsigned long READ_EVERY_MS = 2000; // bacaan baru dikirim setiap 2 detik
20
21void btWrite(const char *text);
22void onValue(const char *key, const char *value);
23void sendAll();
24void onLinkLost();
25
26// ── Aplikasi mengirim baris "kunci=nilai"; saat menerima "?" papan mengirim semua nilainya ──
27char line[65];
28uint8_t lineLen = 0;
29unsigned long lastRxMs = 0;
30
31bool is(const char *a, const char *b) { return strcmp(a, b) == 0; }
32bool isOn(const char *v) { return v[0] == '1'; }
33
34void sendText(const char *key, const char *value) {
35 char out[72];
36 snprintf(out, sizeof(out), "%s=%s\n", key, value);
37 btWrite(out);
38}
39
40void sendInt(const char *key, long value) {
41 char text[12];
42 snprintf(text, sizeof(text), "%ld", value);
43 sendText(key, text);
44}
45
46void sendFloat(const char *key, float value) {
47 char text[16];
48 dtostrf(value, 1, 1, text);
49 sendText(key, text);
50}
51
52void handleLine(char *text) {
53 char *eq = strchr(text, '=');
54 if (eq == nullptr) {
55 if (text[strlen(text) - 1] == '?') {
56 btWrite("@v=1.0\n"); // baris "@v" memberi tahu aplikasi versi kodenya
57 sendAll();
58 }
59 return;
60 }
61 *eq = '\0';
62 onValue(text, eq + 1);
63}
64
65void feed(char c) {
66 lastRxMs = millis();
67 if (c == '\n' || c == '\r') {
68 if (lineLen == 0) return;
69 line[lineLen] = '\0';
70 lineLen = 0;
71 handleLine(line);
72 } else if (lineLen < sizeof(line) - 1) {
73 line[lineLen++] = c;
74 }
75}
76
77// ── Bluetooth (Nordic UART) ──
78#define UART_SERVICE "6E400001-B5A3-F393-E0A9-E50E24DCCA9E"
79#define UART_RX "6E400002-B5A3-F393-E0A9-E50E24DCCA9E"
80#define UART_TX "6E400003-B5A3-F393-E0A9-E50E24DCCA9E"
81
82BLECharacteristic *txChar = nullptr;
83volatile bool linked = false;
84volatile bool linkLost = false;
85// byte yang masuk dipindah dari tugas Bluetooth ke loop() lewat buffer cincin kecil
86const int RX_SIZE = 256;
87volatile uint8_t rxBuf[RX_SIZE];
88volatile int rxHead = 0, rxTail = 0;
89
90class ServerEvents : public BLEServerCallbacks {
91 void onConnect(BLEServer *server) override { linked = true; }
92 void onDisconnect(BLEServer *server) override { linked = false; linkLost = true; }
93};
94
95class RxEvents : public BLECharacteristicCallbacks {
96 void onWrite(BLECharacteristic *c) override {
97 auto v = c->getValue();
98 for (size_t i = 0; i < v.length(); i++) {
99 int next = (rxHead + 1) % RX_SIZE;
100 if (next == rxTail) break;
101 rxBuf[rxHead] = (uint8_t)v[i];
102 rxHead = next;
103 }
104 }
105};
106
107// baris dikirim dalam paket 20 byte (bisa di semua ponsel)
108void btWrite(const char *text) {
109 if (!linked || txChar == nullptr) return;
110 size_t n = strlen(text);
111 for (size_t i = 0; i < n; i += 20) {
112 size_t len = n - i < 20 ? n - i : 20;
113 txChar->setValue((uint8_t *)text + i, len);
114 txChar->notify();
115 delay(4);
116 }
117}
118
119void btBegin() {
120 BLEDevice::init(BLE_NAME);
121 BLEServer *server = BLEDevice::createServer();
122 server->setCallbacks(new ServerEvents());
123 BLEService *uart = server->createService(UART_SERVICE);
124 txChar = uart->createCharacteristic(UART_TX, BLECharacteristic::PROPERTY_NOTIFY);
125 txChar->addDescriptor(new BLE2902());
126 BLECharacteristic *rx = uart->createCharacteristic(UART_RX, BLECharacteristic::PROPERTY_WRITE | BLECharacteristic::PROPERTY_WRITE_NR);
127 rx->setCallbacks(new RxEvents());
128 uart->start();
129 BLEAdvertisementData adv;
130 adv.setFlags(0x06);
131 adv.setCompleteServices(BLEUUID(UART_SERVICE));
132 BLEAdvertisementData scan;
133 scan.setName(BLE_NAME);
134 BLEAdvertising *advertising = BLEDevice::getAdvertising();
135 advertising->setAdvertisementData(adv);
136 advertising->setScanResponseData(scan);
137 BLEDevice::startAdvertising();
138}
139
140void btPoll() {
141 while (rxTail != rxHead) {
142 char c = (char)rxBuf[rxTail];
143 rxTail = (rxTail + 1) % RX_SIZE;
144 feed(c);
145 }
146 if (linkLost) {
147 linkLost = false;
148 onLinkLost();
149 delay(100);
150 BLEDevice::startAdvertising();
151 }
152}
153
154// ── ESP32 ──
155DHT dht(DHT_PIN, DHT11);
156float temperature = NAN, humidity = NAN;
157unsigned long lastReadMs = 0;
158
159// jika sensor gagal dibaca, aplikasi menerima "@err=dht": periksa kabelnya
160void readSensor() {
161 float t = dht.readTemperature();
162 float h = dht.readHumidity();
163 if (isnan(t) || isnan(h)) {
164 btWrite("@err=dht\n");
165 return;
166 }
167 temperature = t;
168 humidity = h;
169}
170
171void sendReadings() {
172 if (isnan(temperature)) return;
173 sendFloat("sicaklik", temperature);
174 sendInt("nem", lround(humidity));
175}
176
177void onValue(const char *key, const char *value) {
178}
179
180void sendAll() {
181 if (isnan(temperature)) readSensor();
182 sendReadings();
183}
184
185void onLinkLost() {
186}
187
188void setup() {
189 Serial.begin(115200);
190 dht.begin();
191 btBegin();
192 Serial.print(F("BlueGrays Bluetooth: "));
193 Serial.println(BLE_NAME);
194}
195
196void loop() {
197 btPoll();
198 if (millis() - lastReadMs >= READ_EVERY_MS) {
199 lastReadMs = millis();
200 readSensor();
201 sendReadings();
202 }
203}
204FAQ
Apakah bisa dipakai dengan iPhone?
Bisa. Board memakai Bluetooth Low Energy (BLE) bawaan ESP32, dan aplikasi BlueGrays tersambung di iPhone maupun Android. Modul Bluetooth klasik seperti HC-05 atau HC-06 tidak bisa tersambung ke iPhone, karena itu proyek ini tidak memakainya. Jangan coba memasangkan board dari pengaturan Bluetooth ponsel; koneksinya hanya dibuat oleh aplikasi.
Bisakah saya memakai DHT22 sebagai ganti DHT11?
Bisa. DHT22 (AM2302) mengukur lebih akurat dan dengan rentang lebih lebar: sekitar -40 sampai 80 °C, ±0,5 °C. Kabelnya tetap sama. Templat di aplikasi dibuat untuk DHT11, jadi ganti DHT11 menjadi DHT22 di baris DHT dht(DHT_PIN, DHT11), lalu unggah lagi. Skala grafik di panel disetel untuk rentang DHT11 (0 sampai 50 °C).
Kenapa nilainya berubah tiap 2 detik, dan seberapa akurat?
DHT11 tidak bisa dibaca lebih sering dari sekali per detik, jadi kode mengukur dan mengirim setiap 2 detik dengan READ_EVERY_MS = 2000. Sensor ini mengukur 0 sampai 50 °C dan kelembapan 20 sampai 90 %, dengan galat sekitar ±2 °C dan ±5 % kelembapan. Cukup untuk memantau ruangan; kalau ingin lebih akurat, pakai DHT22.
Apakah hasil ukur tersimpan saat ponsel jauh?
Tidak. Board hanya mengirim nilai saat itu dan tidak menyimpan riwayat. Grafik digambar dari nilai yang masuk selama panel terbuka dan board tersambung; kalau ponsel keluar jangkauan atau aplikasi ditutup, tidak ada titik baru. Saat tersambung lagi, aplikasi mengirim ? dan board langsung mengirim nilai terakhirnya.
