Nhiệt độ và độ ẩm DHT22 với ESP32 (hiển thị trên LCD)
Dự án này đo nhiệt độ và độ ẩm môi trường bằng cảm biến DHT22 và hiển thị dữ liệu theo thời gian thực trên LCD I2C 16x2. Dữ liệu được đọc từ cảm biến bằng giao thức một dây qua thư viện Adafruit DHT. Dự án là nền tảng cho trạm thời tiết IoT, tự động hóa nhà thông minh hay hệ thống giám sát môi trường trong nhà kính. Giao tiếp với DHT22 qua chân GPIO 4 của ESP32.

Video
Sơ đồ mạch

Mã nguồn
1// ─────────────────────────────────────────
2// BlueGrays · bluegrays.com
3// ESP32 DHT22 Temperature and Humidity (with LCD Display)
4// ─────────────────────────────────────────
5// Reads temperature and humidity from the DHT22 every 2 s and shows them
6// on a 16x2 I2C LCD. If a reading fails, the screen shows a wiring and
7// pull-up warning.
8//
9// Pins:
10// GPIO 4 -> DHT22 DATA
11// 10k pull-up between DATA and VCC
12// GPIO 21 -> LCD SDA, GPIO 22 -> LCD SCL
13// DHT22 VCC -> 3V3, LCD VCC -> 5V (VIN)
14// All GNDs common
15
16#include <Wire.h>
17#include <LiquidCrystal_I2C.h>
18#include <DHT.h>
19
20// Pin definitions
21const int DHT_PIN = 4;
22#define DHT_TYPE DHT22
23
24DHT dht(DHT_PIN, DHT_TYPE);
25
26// LCD addr 0x27 or 0x3F
27LiquidCrystal_I2C lcd(0x27, 16, 2);
28
29// DHT22 needs at least 2 s between reads
30const unsigned long READ_INTERVAL = 2000;
31unsigned long lastRead = 0;
32
33void setup() {
34 // DevKit V1 default I2C pins
35 Wire.begin(21, 22);
36 lcd.init();
37 lcd.backlight();
38
39 // Splash screen 3 s
40 lcd.setCursor(3, 0);
41 lcd.print("BlueGrays");
42 lcd.setCursor(3, 1);
43 lcd.print("DHT22 v1.0");
44 delay(3000);
45 lcd.clear();
46
47 dht.begin();
48}
49
50void loop() {
51 // Read every 2 s without delay()
52 if (millis() - lastRead >= READ_INTERVAL) {
53 lastRead = millis();
54
55 float h = dht.readHumidity();
56 float t = dht.readTemperature();
57
58 lcd.clear();
59
60 // NaN = wiring/pullup issue
61 if (isnan(h) || isnan(t)) {
62 lcd.setCursor(0, 0);
63 lcd.print("Sensor read fail");
64 lcd.setCursor(0, 1);
65 lcd.print("Wire+10k pullup");
66 } else {
67 // Temperature
68 lcd.setCursor(0, 0);
69 lcd.print("Temp. :");
70 lcd.print(t, 1);
71 lcd.print("C");
72 // Humidity, DHT22 gives decimals
73 lcd.setCursor(0, 1);
74 lcd.print("Humidity:");
75 lcd.print(h, 1);
76 lcd.print("%");
77 }
78 }
79}
80
FAQ
DHT22 và DHT11 khác nhau thế nào?
DHT22 chính xác hơn (±0,5 °C, ±2–5% độ ẩm), đo được dải rộng hơn (−40 đến 80 °C) và có độ phân giải 0,1. DHT11 rẻ hơn nhưng chỉ đạt ±2 °C và độ phân giải số nguyên.
Có bắt buộc điện trở kéo lên 10 kΩ không?
Cảm biến DHT22 trần cần điện trở kéo lên 10 kΩ cho đường dữ liệu. Với module 3 chân gắn trên bo mạch, điện trở này thường đã có sẵn.
LCD 5 V, ESP32 3,3 V; hai thứ có chạy cùng nhau được không?
Module LCD I2C hiển thị rõ hơn ở 5 V. Nếu các điện trở kéo lên trên đường SDA/SCL của module cấp nguồn 5 V được nối lên 5 V, dùng mạch chuyển mức là cách an toàn nhất; dù nhiều người nối trực tiếp, cách đó đẩy ESP32 đến giới hạn.
Mình có gửi dữ liệu qua Internet được không?
Được, bạn có thể dùng Wi-Fi của ESP32 để gửi số đo lên ThingSpeak, Blynk hoặc máy chủ của riêng bạn và xem biểu đồ trên điện thoại.
