Tưới cây IoT với ESP32 (cảm biến độ ẩm đất + máy bơm)
Để máy bơm tự chạy khi đất trong chậu khô, và theo dõi trực tiếp độ ẩm đất trên điện thoại. Dự án này là hướng dẫn từng bước cho mẫu IoT Độ ẩm đất + máy bơm trong ứng dụng, làm với ESP32, cảm biến độ ẩm đất, rơ-le và máy bơm nước mini. Vào Xưởng › Thiết bị › Thêm thiết bị; Ohmi chuẩn bị code với khóa thiết bị của riêng bạn. Code trên trang này chỉ là ví dụ: khóa và thông tin Wi-Fi là giá trị giữ chỗ.

Điều khiển thiết bị này từ ứng dụng
Kết nối ESP32 hoặc Raspberry Pi Pico W với Wi-Fi, rồi bật tắt và xem số đo trực tiếp từ điện thoại. Ohmi chuẩn bị code; bạn chỉ cần nhập thông tin Wi-Fi và nạp vào bo mạch.
Mẫu trong ứng dụng: Độ ẩm đất + bơm
- Ở đâu trong ứng dụng?Thêm thiết bị mới từ tab Công cụ hoặc Xưởng › Thiết bị rồi chọn mẫu này.
- Thư viện ArduinoMở Library Manager trong Arduino IDE, tìm BlueGraysIoT và cài đặt.
Gói miễn phí có 1 thiết bị, 1 biểu đồ và lịch sử 24 giờ. Premium thêm nhiều thiết bị hơn, nhiều biểu đồ hơn và lịch sử dài hơn.
Video
Sơ đồ mạch

Mã nguồn
1// ─────────────────────────────────────────
2// BlueGrays · bluegrays.com
3// ESP32 IoT Plant Watering (Soil Sensor + Pump)
4// ─────────────────────────────────────────
5// The "Soil moisture + pump" IoT template from the BlueGrays app: the soil
6// moisture sensor measures every 2 seconds and sends the value to the app,
7// the relay starts the pump when the moisture drops below the watering
8// threshold and stops it 10 points above it; you can also control the pump
9// and the threshold from your phone. Ohmi prepares the real code in the
10// app with your own device key (Workshop › Devices › Add a device); the
11// code here is an example, the device key and Wi-Fi details are
12// placeholders. Library Manager: BlueGraysIoT (with its dependencies). The
13// board only joins 2.4 GHz Wi-Fi networks. The relay switches on LOW.
14// Safety: power the pump from its own battery holder (4 x AA), not from
15// the board; keep the board, relay and batteries away from water in a
16// closed box; never run the pump dry.
17//
18// Pins:
19// GPIO34 -> Soil moisture sensor AO
20// 3V3, GND -> Soil moisture sensor VCC, GND
21// GPIO26 -> Relay module IN
22// 5V, GND -> Relay module VCC, GND
23// Relay COM -> battery holder (+), NO -> pump (+), pump (-) -> battery holder (-); the pump
24// runs on its own 4 x AA
25// Pico W: moisture sensor AO GP26, relay IN GP15
26
27/*
28 * Soil moisture + pump · BlueGrays IoT
29 * BlueGrays · bluegrays.com
30 * Do not share this code: it contains your device key and Wi-Fi password.
31 */
32
33#include <BlueGraysIoT.h>
34
35const char *DEVICE_KEY = "YOUR_DEVICE_KEY";
36const char *WIFI_NAME = "YOUR_WIFI_NAME";
37const char *WIFI_PASSWORD = "YOUR_WIFI_PASSWORD";
38
39BlueGraysIoT bg(DEVICE_KEY);
40
41const int RELAY_PIN = 26;
42const bool RELAY_ACTIVE_LOW = true; // most relay modules switch on LOW
43void setRelay(bool on) {
44 if (RELAY_ACTIVE_LOW) {
45 if (on) { pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, LOW); }
46 else { pinMode(RELAY_PIN, INPUT); } // off releases the pin: a 3.3 V HIGH is not enough to turn a 5 V module off
47 } else {
48 pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, on ? HIGH : LOW);
49 }
50}
51const int SOIL_PIN = 34;
52const int SOIL_DRY = 3200; // reading in dry soil
53const int SOIL_WET = 1300; // reading in wet soil
54int threshold = 30; bool pump = false; unsigned long lastReadMs = 0;
55
56void setup() {
57 Serial.begin(115200);
58 setRelay(false);
59 analogReadResolution(12);
60 bg.onSwitch("pompa", [](bool on) { pump = on; setRelay(on); });
61 bg.onNumber("esik", [](float v) { threshold = (int)v; });
62 bg.setDeadband("toprak", 1.0);
63 bg.setDebug(Serial);
64 bg.setLanguage(BG_LANG_EN);
65 bg.begin(WIFI_NAME, WIFI_PASSWORD);
66}
67
68void loop() {
69 bg.loop(); // avoid long delay() calls here
70 if (millis() - lastReadMs >= 2000) {
71 lastReadMs = millis();
72 int pct = constrain(map(analogRead(SOIL_PIN), SOIL_DRY, SOIL_WET, 0, 100), 0, 100);
73 bg.send("toprak", pct);
74 // Turn the pump on below the threshold, off 10 points above it
75 if (pct < threshold && !pump) { pump = true; setRelay(true); bg.send("pompa", true); }
76 if (pct > threshold + 10 && pump) { pump = false; setRelay(false); bg.send("pompa", false); }
77 }
78}
79FAQ
Mình có thể nạp thẳng code trên trang này vào bo mạch không?
Bạn có thể nạp, nhưng nó sẽ không kết nối được: khóa thiết bị và thông tin Wi-Fi trong đó chỉ là giá trị giữ chỗ. Trong ứng dụng, vào Xưởng › Thiết bị › Thêm thiết bị và chọn mẫu Độ ẩm đất + máy bơm; Ohmi chuẩn bị code với khóa, tên mạng và mật khẩu của bạn. Hãy sao chép code đó và nạp vào bo mạch. Sau này bạn có thể xem toàn bộ code trong Thiết bị › Code và khóa.
Nó có chạy với Pico W không?
Được. Chọn Pico W làm bo mạch khi thêm thiết bị; code giữ nguyên, chỉ có chân và các giá trị hiệu chuẩn thay đổi: cảm biến độ ẩm nối vào GP26 (một ngõ vào analog) và rơ-le nối vào GP15. Trong Arduino IDE, hãy cài gói "pico" từ Boards Manager. Mạch và ảnh trên trang này được làm với ESP32.
Vì sao máy bơm có pin riêng?
Dòng điện mà máy bơm tiêu thụ và nhiễu do động cơ của nó gây ra có thể làm bo mạch khởi động lại. Vì vậy máy bơm chạy bằng hộp đựng pin 4 x AA và chỉ đi qua các cực COM và NO của rơ-le; nó không có dây nối nào với bo mạch. Hãy để bo mạch, rơ-le và hộp đựng pin trong hộp kín, tránh xa nước, và giữ các mối nối dây luôn khô. Máy bơm chỉ được chạy khi ngập trong nước; nếu chạy khô, nó nóng lên và hỏng trong vài phút. Hãy tháo pin ra khi lắp ống hoặc nhấc máy bơm ra khỏi nước.
Khi nào máy bơm chạy, và nếu mình bật tắt bằng tay thì sao?
Bo mạch đo độ ẩm mỗi 2 giây. Khi độ ẩm giảm xuống dưới Ngưỡng tưới trong ứng dụng (ban đầu là 30%), máy bơm bật, và tắt khi độ ẩm cao hơn ngưỡng 10 điểm; khoảng cách này giúp máy bơm không bật tắt liên tục. Bạn cũng có thể chạm vào công tắc Máy bơm bằng tay, nhưng quy tắc tự động được ưu tiên: nếu bạn tắt khi đất còn dưới ngưỡng, máy bơm bật lại trong vòng 2 giây, và nếu bạn bật khi đất đã cao hơn ngưỡng 10 điểm, nó tắt ngay. Hãy đặt ngưỡng phù hợp với chậu cây của bạn.
