Dải LED RGB IoT với ESP32 (WS2812B)
Điều khiển ánh sáng trong phòng từ điện thoại: chọn màu, chỉnh độ sáng, bật hiệu ứng cầu vồng hoặc nhịp thở. Dự án này là hướng dẫn từng bước cho mẫu IoT Dải LED RGB trong ứng dụng, làm với ESP32 và dải WS2812B 30 LED bằng ba sợi dây. Vào Xưởng › Thiết bị › Thêm thiết bị và chọn Dải LED RGB; Ohmi chuẩn bị code với khóa thiết bị của riêng bạn. Code trên trang này chỉ là ví dụ: khóa và thông tin Wi-Fi là giá trị giữ chỗ.

Điều khiển thiết bị này từ ứng dụng
Kết nối ESP32 hoặc Raspberry Pi Pico W với Wi-Fi, rồi bật tắt và xem số đo trực tiếp từ điện thoại. Ohmi chuẩn bị code; bạn chỉ cần nhập thông tin Wi-Fi và nạp vào bo mạch.
Mẫu trong ứng dụng: Dải LED RGB
- Ở đâu trong ứng dụng?Thêm thiết bị mới từ tab Công cụ hoặc Xưởng › Thiết bị rồi chọn mẫu này.
- Thư viện ArduinoMở Library Manager trong Arduino IDE, tìm BlueGraysIoT và cài đặt.
Gói miễn phí có 1 thiết bị, 1 biểu đồ và lịch sử 24 giờ. Premium thêm nhiều thiết bị hơn, nhiều biểu đồ hơn và lịch sử dài hơn.
Video
Sơ đồ mạch

Mã nguồn
1// ─────────────────────────────────────────
2// BlueGrays · bluegrays.com
3// ESP32 IoT RGB LED Strip (WS2812B)
4// ─────────────────────────────────────────
5// The "RGB LED strip" IoT template from the BlueGrays app: change the
6// light, color, brightness and effect (solid, rainbow, breathe, blink, color cycle) of
7// a 30-LED WS2812B strip from your phone. Ohmi prepares the real code in
8// the app with your own device key (Workshop › Devices › Add a device);
9// the code here is an example, the device key and Wi-Fi details are
10// placeholders. Library Manager: BlueGraysIoT (with its dependencies) and
11// Adafruit NeoPixel. The board only joins 2.4 GHz Wi-Fi networks. For 30
12// LEDs at full brightness, power the strip from a separate 5 V 2 A adapter
13// and join the grounds.
14//
15// Pins:
16// GPIO13 -> WS2812B strip DIN
17// 5V, GND -> Strip 5V, GND
18// Pico W: strip DIN GP2, 5V VBUS
19
20/*
21 * RGB LED strip · BlueGrays IoT
22 * BlueGrays · bluegrays.com
23 * Do not share this code: it contains your device key and Wi-Fi password.
24 */
25
26#include <BlueGraysIoT.h>
27#include <Adafruit_NeoPixel.h> // Library Manager: 'Adafruit NeoPixel'
28
29const char *DEVICE_KEY = "YOUR_DEVICE_KEY";
30const char *WIFI_NAME = "YOUR_WIFI_NAME";
31const char *WIFI_PASSWORD = "YOUR_WIFI_PASSWORD";
32
33BlueGraysIoT bg(DEVICE_KEY);
34
35const int LED_COUNT = 30;
36Adafruit_NeoPixel strip(LED_COUNT, 13, NEO_GRB + NEO_KHZ800);
37bool isOn = false; uint8_t cr = 255, cg = 255, cb = 255; int brightness = 70; String effect = "sabit";
38void paint() {
39 strip.setBrightness(isOn ? map(brightness, 0, 100, 0, 255) : 0);
40 for (int i = 0; i < LED_COUNT; i++) strip.setPixelColor(i, strip.gamma32(strip.Color(cr, cg, cb))); // gamma: the LEDs match the color on screen
41 strip.show();
42}
43
44void setup() {
45 Serial.begin(115200);
46 strip.begin();
47 paint();
48 bg.onSwitch("acik", [](bool on) { isOn = on; paint(); });
49 bg.onColor("renk", [](uint8_t r, uint8_t g, uint8_t b) { cr = r; cg = g; cb = b; paint(); });
50 bg.onNumber("parlaklik", [](float v) { brightness = (int)v; paint(); });
51 bg.onChoice("efekt", [](const char *e) { effect = e; paint(); });
52 bg.setDebug(Serial);
53 bg.setLanguage(BG_LANG_EN);
54 bg.begin(WIFI_NAME, WIFI_PASSWORD);
55}
56
57void loop() {
58 bg.loop(); // avoid long delay() calls here
59 if (isOn && effect == "gokkusagi") {
60 static uint16_t hue = 0; hue += 64;
61 for (int i = 0; i < LED_COUNT; i++) strip.setPixelColor(i, strip.gamma32(strip.ColorHSV(hue + i * 2000)));
62 strip.show(); delay(5);
63 } else if (isOn && effect == "nefes") { // slowly fades out and in
64 float wave = (sin(millis() / 600.0) + 1.0) / 2.0;
65 strip.setBrightness((uint8_t)(map(brightness, 0, 100, 0, 255) * (0.15 + 0.85 * wave)));
66 strip.show(); delay(10);
67 } else if (isOn && effect == "yanip_sonme") { // blinks every half second
68 strip.setBrightness((millis() / 500) % 2 ? map(brightness, 0, 100, 0, 255) : 0);
69 strip.show(); delay(10);
70 } else if (isOn && effect == "renk_dongusu") { // whole strip one color, smooth hue shift
71 static uint16_t hue = 0; hue += 16;
72 uint32_t c = strip.gamma32(strip.ColorHSV(hue));
73 for (int i = 0; i < LED_COUNT; i++) strip.setPixelColor(i, c);
74 strip.show(); delay(10);
75 }
76}
77FAQ
Mình có thể nạp thẳng code trên trang này vào bo mạch không?
Bạn có thể nạp, nhưng nó sẽ không kết nối được: khóa thiết bị và thông tin Wi-Fi trong đó chỉ là giá trị giữ chỗ. Trong ứng dụng, vào Xưởng › Thiết bị › Thêm thiết bị và chọn Dải LED RGB; Ohmi chuẩn bị code với khóa, tên mạng và mật khẩu của bạn. Hãy sao chép code đó và nạp vào bo mạch. Sau này bạn có thể xem toàn bộ code trong Thiết bị › Code và khóa.
Nó có chạy với Pico W không?
Được. Chọn Pico W làm bo mạch khi thêm thiết bị; code giữ nguyên, chỉ có chân dữ liệu thay đổi: chân DIN của dải LED nối vào GP2, 5V nối vào VBUS và GND nối vào GND. Trong Arduino IDE, hãy cài gói "pico" từ Boards Manager và Adafruit NeoPixel từ Library Manager. Mạch và ảnh trên trang này được làm với ESP32.
Mình có thể cấp nguồn cho dải LED từ USB không?
Thử ngắn thì được, nhưng hãy cẩn thận: mỗi LED tiêu thụ khoảng 60 mA khi sáng trắng tối đa, nên 30 LED ở độ sáng tối đa có thể lên tới 1,8 A. Mức này vượt quá khả năng của USB và bo mạch. Khi dùng lâu dài hoặc độ sáng cao, hãy cấp nguồn cho dải LED từ một adapter 5 V 2 A riêng và nối GND của adapter với GND của bo mạch. Code được viết cho 30 LED; nếu dải của bạn dài hơn, hãy đổi LED_COUNT và chọn adapter phù hợp.
Mình có thể thay đổi những gì trong ứng dụng?
Màn hình thiết bị có bốn điều khiển: công tắc Ánh sáng bật tắt dải LED, bộ chọn Màu tô tất cả LED một màu, thanh trượt Độ sáng đi từ 0 đến 100, và danh sách Hiệu ứng có Cố định, Cầu vồng, Nhịp thở hoặc Nhấp nháy. Sau khi mất điện, màu, độ sáng và hiệu ứng cuối cùng của bạn trở lại ngay khi bo mạch kết nối lại.
