Cara Memakai LED RGB: Mencampur Warna dengan Arduino, Common Anode vs Common Cathode

LED RGB adalah tiga LED terpisah dalam satu kemasan: merah, hijau, dan biru. Dengan mengatur kecerahan masing-masing secara terpisah, kamu bisa membuat hampir semua warna yang kamu mau, dari kuning sampai sian dan dari ungu sampai oranye. Setiap piksel di layar komputer bekerja dengan prinsip yang sama. Ini salah satu komponen Arduino paling seru untuk lampu status, lampu suasana, dan indikator notifikasi berwarna.

Bagaimana cara kerja LED RGB?

Warna cahaya bercampur secara aditif: merah dan hijau bersama terlihat kuning, hijau dan biru menghasilkan sian, merah dan biru menghasilkan ungu (magenta), dan ketiganya bersama menghasilkan putih. Arduino mengatur kecerahan setiap channel dari 0 sampai 255 dengan PWM. Secara teori, itu memberi 256 × 256 × 256 ≈ 16,7 juta kombinasi. PWM menyalakan dan mematikan LED ratusan kali per detik; matamu tidak bisa melihat kedipannya dan hanya menangkap kecerahan rata-ratanya.

Common cathode atau common anode?

Kaki terpanjang dari empat kaki LED RGB adalah pin bersama yang dipakai ketiga LED. Kalau pin itu menyatukan katoda ketiga LED, LED-nya disebut common cathode; kalau menyatukan anodanya, disebut common anode. Dari luar keduanya terlihat sama, tetapi pengkabelan dan kodenya berkebalikan:

Urutan pin dan pengkabelan Arduino

Pada LED RGB 5 mm yang umum, urutan pinnya adalah merah, bersama (terpanjang), hijau, biru, tetapi karena bisa berbeda antarprodusen, menguji setiap kaki adalah cara paling aman. Setiap warna dihubungkan melalui resistornya sendiri ke pin PWM. Di Arduino Uno, pin PWM adalah yang bertanda ~: 3, 5, 6, 9, 10, dan 11.

Nilai resistor: resistor terpisah untuk setiap warna

Setiap warna butuh tegangan berbeda untuk menyala (tegangan maju): sekitar 2,0 V untuk merah dan 3,0–3,2 V untuk hijau dan biru. Dengan target 20 mA di 5 V, merah butuh (5 − 2,0) / 0,020 = 150 Ω, sedangkan hijau dan biru butuh (5 − 3,2) / 0,020 ≈ 100 Ω. Dalam praktiknya, memasang 220 Ω di ketiganya aman dan masih cukup terang; keseimbangan warnanya bisa kamu atur di kode. Untuk menghitung nilaimu sendiri, pakai kalkulator resistor LED, dan untuk tegangan maju setiap warna, lihat tabel tegangan LED.

Mencampur warna dengan Arduino

Kode di bawah membungkus ketiga channel dalam satu fungsi setColor() dan menampilkan tujuh warna secara bergantian. Kalau LED-mu common anode, cukup ubah COMMON_ANODE menjadi true; fungsinya akan membalik nilainya untukmu.

1const int R_PIN = 9;
2const int G_PIN = 10;
3const int B_PIN = 11;
4const bool COMMON_ANODE = false;   // ortak anotsa true yap / set true for common anode
5
6void setColor(int r, int g, int b) {
7  if (COMMON_ANODE) { r = 255 - r; g = 255 - g; b = 255 - b; }
8  analogWrite(R_PIN, r);
9  analogWrite(G_PIN, g);
10  analogWrite(B_PIN, b);
11}
12
13void setup() {
14  pinMode(R_PIN, OUTPUT);
15  pinMode(G_PIN, OUTPUT);
16  pinMode(B_PIN, OUTPUT);
17}
18
19void loop() {
20  setColor(255, 0, 0);     delay(1000);  // kırmızı / red
21  setColor(0, 255, 0);     delay(1000);  // yeşil / green
22  setColor(0, 0, 255);     delay(1000);  // mavi / blue
23  setColor(255, 255, 0);   delay(1000);  // sarı / yellow
24  setColor(0, 255, 255);   delay(1000);  // turkuaz / cyan
25  setColor(255, 0, 255);   delay(1000);  // mor / magenta
26  setColor(255, 255, 255); delay(1000);  // beyaz / white
27}

Transisi warna yang halus: efek pelangi

Daripada melompat dari satu warna ke warna lain, kalau kamu menurunkan satu channel sambil menaikkan channel lain, cahayanya mengalir halus dari merah ke hijau, hijau ke biru, lalu kembali ke merah. Loop di bawah memakai fungsi setColor() yang sama; ubah nilai delay untuk mengatur kecepatannya.

1// setColor() ve pin tanımları yukarıdaki gibi / setColor() and pins as above
2void loop() {
3  for (int i = 0; i < 256; i++) { setColor(255 - i, i, 0); delay(8); }  // kırmızı → yeşil / red → green
4  for (int i = 0; i < 256; i++) { setColor(0, 255 - i, i); delay(8); }  // yeşil → mavi / green → blue
5  for (int i = 0; i < 256; i++) { setColor(i, 0, 255 - i); delay(8); }  // mavi → kırmızı / blue → red
6}

Memilih warna dengan potensiometer

Kalau kamu menghubungkan tiga potensiometer ke A0, A1, dan A2, masing-masing bisa kamu pakai sebagai kenop untuk satu channel warna. analogRead() mengembalikan nilai dari 0 sampai 1023; membaginya dengan 4 menghasilkan rentang 0–255 yang dibutuhkan PWM. Pengkabelan potensiometer dijelaskan di Apa Itu Potensiometer?

1// A0, A1, A2'de üç potansiyometre; setColor() yukarıdaki gibi
2// three pots on A0, A1, A2; setColor() as above
3void loop() {
4  int r = analogRead(A0) / 4;   // 0–1023 → 0–255
5  int g = analogRead(A1) / 4;
6  int b = analogRead(A2) / 4;
7  setColor(r, g, b);
8}

LED RGB dengan ESP32 dan Raspberry Pi Pico

Di ESP32 dengan Arduino core terbaru (3.x), analogWrite() berfungsi di pin output mana pun, jadi kode di atas langsung berjalan setelah kamu mengganti nomor pinnya. Yang perlu diperhatikan hanya tegangan: pinnya mengeluarkan 3,3 V, jadi channel hijau dan biru, yang tegangan majunya mendekati 3 V, lebih redup. Di 3,3 V pakai resistor kecil seperti 47–100 Ω, atau nyalakan LED dari 5 V melalui transistor kalau kamu ingin benar-benar terang. Di Pico, kelas PWM MicroPython menerima nilai dari 0 sampai 65535:

1from machine import Pin, PWM
2import time
3
4pins = [PWM(Pin(n)) for n in (11, 12, 13)]   # GP11 R, GP12 G, GP13 B
5for p in pins:
6    p.freq(1000)
7
8def set_color(r, g, b):                       # 0–255
9    for p, v in zip(pins, (r, g, b)):
10        p.duty_u16(v * 257)                   # 0–65535 (ortak anotta 65535 - v * 257)
11
12while True:
13    set_color(255, 0, 0); time.sleep(1)       # kırmızı / red
14    set_color(0, 255, 0); time.sleep(1)       # yeşil / green
15    set_color(0, 0, 255); time.sleep(1)       # mavi / blue

LED RGB biasa atau LED addressable (WS2812B)?

Untuk satu atau dua lampu berwarna, LED RGB biasa adalah solusi paling sederhana dan murah. Kalau kamu ingin mewarnai puluhan LED satu per satu, 6 pin PWM Uno tidak cukup; di situlah kamu beralih ke strip WS2812B, yang mengendalikan ratusan LED lewat satu kabel.

Ide proyek dengan LED RGB

• Lampu suasana: masukkan efek pelangi ke dalam toples buram untuk lampu tidur yang lembut.
• Indikator suhu: gabungkan dengan DHT11 untuk lampu yang menyala biru ketika dingin, hijau ketika sejuk, dan merah ketika panas.
• Pencampur warna: buat warna apa pun secara manual dengan tiga potensiometer.
• Pilih warna dari ponsel: ganti warna lampu dari pemilih warna di halaman web yang disajikan ESP32.
• Lampu notifikasi: kedipkan LED dengan warna tertentu ketika ada email atau pesan baru.
• Warna dari keypad: tampilkan warna yang berbeda sesuai angka yang diketik di keypad.

Kesalahan umum dan cara mengatasinya

• Warnanya terbalik: kamu mengendalikan LED common anode seolah-olah common cathode; ubah COMMON_ANODE menjadi true.
• Satu warna tidak pernah menyala: urutan pinnya mungkin berbeda dari dugaanmu; uji setiap kaki satu per satu dengan resistor.
• Transisi patah-patah, tanpa gradasi: LED terpasang di pin non-PWM; di Uno, pin seperti itu hanya bisa menyala penuh atau mati.
• Warna kacau ketika buzzer berbunyi: di Uno, tone() memakai Timer2 dan merusak PWM di pin 3 dan 11; pindahkan LED RGB ke pin seperti 5, 6, 9, dan 10.
• Tidak memasang resistor: arus yang terlalu besar lama-lama merusak LED dan pin Arduino.
• Sangat redup di ESP32: di 3,3 V, hijau dan biru sudah di batasnya; pakai resistor lebih kecil atau transistor.

Kalau kamu ingin memahami dasar-dasar LED dan kenapa LED butuh resistor, lihat Apa Itu LED? dan Apa Itu Resistor? Di aplikasi BlueGrays kamu akan menemukan proyek transisi warna LED RGB, lampu yang dikendalikan keypad, dan pencampur warna lengkap dengan skema rangkaian dan kode.