ES-102중급IoT

ESP32 IoT 식물 물주기 (토양 센서 + 펌프)

화분의 흙이 마르면 펌프가 저절로 돌고, 토양 수분을 휴대폰에서 실시간으로 확인해요. 이 프로젝트는 앱의 토양 수분 + 펌프 IoT 템플릿을 단계별로 안내하는 가이드로, ESP32, 토양 수분 센서, 릴레이, 미니 워터 펌프로 만들어요. 내 작업실 › 내 기기 › 기기 추가로 가면 Ohmi가 내 기기 키로 코드를 준비해 줘요. 이 페이지의 코드는 예시예요. 키와 Wi-Fi 정보는 자리 표시용 값이에요.

0.0(0)
ESP32 IoT 식물 물주기 (토양 센서 + 펌프)
집을 비운 사이 식물이 목마르지 않길 바란다면 이 프로젝트가 딱이에요. 센서가 흙이 얼마나 젖었는지 재고, 수분이 정해 둔 기준값 아래로 떨어지면 릴레이가 펌프를 돌리고, 흙이 충분히 젖으면 멈춰요. 수분은 휴대폰 차트에 쌓이고, 기준값을 바꾸거나 펌프를 돌리는 것도 휴대폰에서 할 수 있어요. 펌프는 보드가 아니라 자기 배터리로 돌기 때문에 물과 전자 부품을 떨어뜨려 두는 법과 안전한 배선도 배워요. 릴레이 참고: 이 보드는 3.3 V로 동작해요. 3.3 V 신호로 작동시킬 수 있는 옵토커플러 릴레이 모듈을 쓰세요. 옵토커플러가 없는 5 V 모듈은 3.3 V 신호로 꺼지지 않을 수 있어요.
IoT · 원격 제어첫 기기는 무료

앱에서 이 기기 제어하기

ESP32 또는 Raspberry Pi Pico W를 Wi-Fi에 연결해 휴대폰으로 켜고 끄며 측정값을 실시간으로 확인해 보세요. 코드는 Ohmi가 준비하니 Wi-Fi 정보만 입력하고 업로드하면 돼요.

앱 내 템플릿: 토양 수분 + 펌프

  • 앱 어디에서 찾을 수 있나요?도구 탭 또는 내 작업실 › 내 기기에서 새 기기를 추가하고 이 템플릿을 선택해 주세요.
  • Arduino 라이브러리Arduino IDE에서 Library Manager를 열고 BlueGraysIoT를 검색해 설치해 주세요.
앱 무료 다운로드

무료 플랜에는 기기 1개, 차트 1개, 24시간 기록이 포함돼요. Premium에서는 더 많은 기기와 차트를 사용하고 기록도 더 오래 보관할 수 있어요.

동영상

회로도

ESP32 IoT 식물 물주기 (토양 센서 + 펌프) - 회로도

소스 코드

C++ (Arduino IDE)
1// ─────────────────────────────────────────
2//   BlueGrays · bluegrays.com
3//   ESP32 IoT Plant Watering (Soil Sensor + Pump)
4// ─────────────────────────────────────────
5// The "Soil moisture + pump" IoT template from the BlueGrays app: the soil
6// moisture sensor measures every 2 seconds and sends the value to the app,
7// the relay starts the pump when the moisture drops below the watering
8// threshold and stops it 10 points above it; you can also control the pump
9// and the threshold from your phone. Ohmi prepares the real code in the
10// app with your own device key (Workshop › Devices › Add a device); the
11// code here is an example, the device key and Wi-Fi details are
12// placeholders. Library Manager: BlueGraysIoT (with its dependencies). The
13// board only joins 2.4 GHz Wi-Fi networks. The relay switches on LOW.
14// Safety: power the pump from its own battery holder (4 x AA), not from
15// the board; keep the board, relay and batteries away from water in a
16// closed box; never run the pump dry.
17//
18// Pins:
19//   GPIO34 -> Soil moisture sensor AO
20//   3V3, GND -> Soil moisture sensor VCC, GND
21//   GPIO26 -> Relay module IN
22//   5V, GND -> Relay module VCC, GND
23//   Relay COM -> battery holder (+), NO -> pump (+), pump (-) -> battery holder (-); the pump
24//   runs on its own 4 x AA
25//   Pico W: moisture sensor AO GP26, relay IN GP15
26
27/*
28 * Soil moisture + pump · BlueGrays IoT
29 * BlueGrays · bluegrays.com
30 * Do not share this code: it contains your device key and Wi-Fi password.
31 */
32
33#include <BlueGraysIoT.h>
34
35const char *DEVICE_KEY = "YOUR_DEVICE_KEY";
36const char *WIFI_NAME = "YOUR_WIFI_NAME";
37const char *WIFI_PASSWORD = "YOUR_WIFI_PASSWORD";
38
39BlueGraysIoT bg(DEVICE_KEY);
40
41const int RELAY_PIN = 26;
42const bool RELAY_ACTIVE_LOW = true;  // most relay modules switch on LOW
43void setRelay(bool on) {
44  if (RELAY_ACTIVE_LOW) {
45    if (on) { pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, LOW); }
46    else { pinMode(RELAY_PIN, INPUT); }  // off releases the pin: a 3.3 V HIGH is not enough to turn a 5 V module off
47  } else {
48    pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, on ? HIGH : LOW);
49  }
50}
51const int SOIL_PIN = 34;
52const int SOIL_DRY = 3200;  // reading in dry soil
53const int SOIL_WET = 1300;  // reading in wet soil
54int threshold = 30; bool pump = false; unsigned long lastReadMs = 0;
55
56void setup() {
57  Serial.begin(115200);
58  setRelay(false);
59  analogReadResolution(12);
60  bg.onSwitch("pompa", [](bool on) { pump = on; setRelay(on); });
61  bg.onNumber("esik", [](float v) { threshold = (int)v; });
62  bg.setDeadband("toprak", 1.0);
63  bg.setDebug(Serial);
64  bg.setLanguage(BG_LANG_EN);
65  bg.begin(WIFI_NAME, WIFI_PASSWORD);
66}
67
68void loop() {
69  bg.loop();  // avoid long delay() calls here
70  if (millis() - lastReadMs >= 2000) {
71    lastReadMs = millis();
72    int pct = constrain(map(analogRead(SOIL_PIN), SOIL_DRY, SOIL_WET, 0, 100), 0, 100);
73    bg.send("toprak", pct);
74    // Turn the pump on below the threshold, off 10 points above it
75    if (pct < threshold && !pump) { pump = true; setRelay(true); bg.send("pompa", true); }
76    if (pct > threshold + 10 && pump) { pump = false; setRelay(false); bg.send("pompa", false); }
77  }
78}
79

FAQ

이 페이지의 코드를 보드에 바로 업로드해도 돼요?

업로드는 되지만 연결되지는 않아요. 코드 안의 기기 키와 Wi-Fi 정보는 자리 표시용 값이에요. 앱에서 내 작업실 › 내 기기 › 기기 추가로 가서 토양 수분 + 펌프 템플릿을 고르면, Ohmi가 내 키, 네트워크 이름, 비밀번호로 코드를 준비해 줘요. 그 코드를 복사해서 업로드하세요. 전체 코드는 나중에 기기 › 코드 및 키에서도 볼 수 있어요.

Pico W로도 돼요?

네. 기기를 추가할 때 보드로 Pico W를 고르세요. 코드는 같고 핀과 보정값만 바뀌어요. 수분 센서는 GP26(아날로그 입력), 릴레이는 GP15에 연결해요. Arduino IDE의 Boards Manager에서 "pico" 패키지를 설치하세요. 이 페이지의 회로와 사진은 ESP32로 만들었어요.

펌프에는 왜 따로 배터리가 있어요?

펌프가 끌어가는 전류와 모터 잡음 때문에 보드가 리셋될 수 있어요. 그래서 펌프는 AA 4개짜리 배터리 홀더로 돌리고, 릴레이의 COM과 NO 단자만 거치며, 보드와는 전선으로 연결되지 않아요. 보드, 릴레이, 배터리 홀더는 닫힌 상자에 넣어 물에서 멀리 두고, 전선 연결부는 마른 상태로 유지하세요. 펌프는 물속에서만 돌려야 해요. 물 없이 돌면 몇 분 안에 뜨거워져서 고장 나요. 호스를 끼우거나 펌프를 물에서 꺼낼 때는 배터리를 빼세요.

펌프는 언제 돌고, 손으로 켜고 끄면 어떻게 돼요?

보드는 2초마다 수분을 재요. 수분이 앱의 급수 기준값(처음에는 30%) 아래로 떨어지면 펌프가 켜지고, 기준값보다 10포인트 높아지면 꺼져요. 이 간격 덕분에 펌프가 딸깍거리며 켜졌다 꺼졌다 하지 않아요. 펌프 스위치를 손으로 눌러도 되지만 자동 규칙이 우선이에요. 흙이 기준값 아래일 때 끄면 2초 안에 다시 켜지고, 흙이 10포인트 위일 때 켜면 바로 꺼져요. 기준값은 화분에 맞게 정하세요.