ESP32 Bluetooth telefon pianinosu
Telefonunu 8 klavişli pianinoya çevir: klavişə basanda ESP32-dəki passiv buzzer həmin notu çalır; internet və ya Wi-Fi lazım deyil. Bu layihə tətbiqdəki Telefon pianinosu Bluetooth şablonunun addım-addım bələdçisidir: bir buzzer və iki jumper naqillə qurulur. Emalatxanam › Cihazlarım › Yeni cihaz əlavə et › Bluetooth yolunu izlə, şablonu seç, Kodu al ilə kodu plataya yüklə. Bu səhifədəki Bluetooth paneli kimi qur düyməsi də sehrbazı bu şablonla açır.

Video
Dövrə sxemi

Mənbə kodu
1// ┌───────────────────────────┐
2// │ BlueGrays · bluegrays.com │
3// │ Bluetooth · ESP32 │
4// │ BG-Piyano │
5// └───────────────────────────┘
6// Telefon pianinosu
7// Arduino IDE-də plata: ESP32 Dev Module
8// BLE kitabxanası ESP32 plata paketi ilə gəlir, ayrıca quraşdırılmır
9
10#include <BLEDevice.h>
11#include <BLEServer.h>
12#include <BLE2902.h>
13
14const char BLE_NAME[] = "BG-Piyano"; // plata bu adla yayım edir, tətbiq onu siyahıda bu adla tapır
15
16// Pinlər: fərqli qoşmusansa, buradan dəyiş
17const int BUZZER_PIN = 25; // passiv buzzer istifadə et (aktiv buzzer yalnız bir ton çıxarır)
18
19void btWrite(const char *text);
20void onValue(const char *key, const char *value);
21void sendAll();
22void onLinkLost();
23
24// ── Tətbiq "açar=dəyər" sətirləri göndərir; "?" gələndə plata bütün dəyərlərini göndərir ──
25char line[65];
26uint8_t lineLen = 0;
27unsigned long lastRxMs = 0;
28
29bool is(const char *a, const char *b) { return strcmp(a, b) == 0; }
30bool isOn(const char *v) { return v[0] == '1'; }
31
32void sendText(const char *key, const char *value) {
33 char out[72];
34 snprintf(out, sizeof(out), "%s=%s\n", key, value);
35 btWrite(out);
36}
37
38void sendInt(const char *key, long value) {
39 char text[12];
40 snprintf(text, sizeof(text), "%ld", value);
41 sendText(key, text);
42}
43
44void sendFloat(const char *key, float value) {
45 char text[16];
46 dtostrf(value, 1, 1, text);
47 sendText(key, text);
48}
49
50void handleLine(char *text) {
51 char *eq = strchr(text, '=');
52 if (eq == nullptr) {
53 if (text[strlen(text) - 1] == '?') {
54 btWrite("@v=1.0\n"); // "@v" sətri tətbiqə kodun versiyasını bildirir
55 sendAll();
56 }
57 return;
58 }
59 *eq = '\0';
60 onValue(text, eq + 1);
61}
62
63void feed(char c) {
64 lastRxMs = millis();
65 if (c == '\n' || c == '\r') {
66 if (lineLen == 0) return;
67 line[lineLen] = '\0';
68 lineLen = 0;
69 handleLine(line);
70 } else if (lineLen < sizeof(line) - 1) {
71 line[lineLen++] = c;
72 }
73}
74
75// ── Bluetooth (Nordic UART) ──
76#define UART_SERVICE "6E400001-B5A3-F393-E0A9-E50E24DCCA9E"
77#define UART_RX "6E400002-B5A3-F393-E0A9-E50E24DCCA9E"
78#define UART_TX "6E400003-B5A3-F393-E0A9-E50E24DCCA9E"
79
80BLECharacteristic *txChar = nullptr;
81volatile bool linked = false;
82volatile bool linkLost = false;
83// gələn baytlar Bluetooth tapşırığından loop()-a kiçik dairəvi bufer vasitəsilə keçir
84const int RX_SIZE = 256;
85volatile uint8_t rxBuf[RX_SIZE];
86volatile int rxHead = 0, rxTail = 0;
87
88class ServerEvents : public BLEServerCallbacks {
89 void onConnect(BLEServer *server) override { linked = true; }
90 void onDisconnect(BLEServer *server) override { linked = false; linkLost = true; }
91};
92
93class RxEvents : public BLECharacteristicCallbacks {
94 void onWrite(BLECharacteristic *c) override {
95 auto v = c->getValue();
96 for (size_t i = 0; i < v.length(); i++) {
97 int next = (rxHead + 1) % RX_SIZE;
98 if (next == rxTail) break;
99 rxBuf[rxHead] = (uint8_t)v[i];
100 rxHead = next;
101 }
102 }
103};
104
105// sətirlər 20 baytlıq paketlərlə göndərilir (hər telefonla işləyir)
106void btWrite(const char *text) {
107 if (!linked || txChar == nullptr) return;
108 size_t n = strlen(text);
109 for (size_t i = 0; i < n; i += 20) {
110 size_t len = n - i < 20 ? n - i : 20;
111 txChar->setValue((uint8_t *)text + i, len);
112 txChar->notify();
113 delay(4);
114 }
115}
116
117void btBegin() {
118 BLEDevice::init(BLE_NAME);
119 BLEServer *server = BLEDevice::createServer();
120 server->setCallbacks(new ServerEvents());
121 BLEService *uart = server->createService(UART_SERVICE);
122 txChar = uart->createCharacteristic(UART_TX, BLECharacteristic::PROPERTY_NOTIFY);
123 txChar->addDescriptor(new BLE2902());
124 BLECharacteristic *rx = uart->createCharacteristic(UART_RX, BLECharacteristic::PROPERTY_WRITE | BLECharacteristic::PROPERTY_WRITE_NR);
125 rx->setCallbacks(new RxEvents());
126 uart->start();
127 BLEAdvertisementData adv;
128 adv.setFlags(0x06);
129 adv.setCompleteServices(BLEUUID(UART_SERVICE));
130 BLEAdvertisementData scan;
131 scan.setName(BLE_NAME);
132 BLEAdvertising *advertising = BLEDevice::getAdvertising();
133 advertising->setAdvertisementData(adv);
134 advertising->setScanResponseData(scan);
135 BLEDevice::startAdvertising();
136}
137
138void btPoll() {
139 while (rxTail != rxHead) {
140 char c = (char)rxBuf[rxTail];
141 rxTail = (rxTail + 1) % RX_SIZE;
142 feed(c);
143 }
144 if (linkLost) {
145 linkLost = false;
146 onLinkLost();
147 delay(100);
148 BLEDevice::startAdvertising();
149 }
150}
151
152// ── ESP32 ──
153void onValue(const char *key, const char *value) {
154 if (is(key, "nota")) { // "nota=Hz" notu çalır, "nota=0" susdurur
155 int hz = atoi(value);
156 if (hz > 0) tone(BUZZER_PIN, hz);
157 else noTone(BUZZER_PIN);
158 }
159}
160
161void sendAll() {
162 sendInt("nota", 0);
163}
164
165void onLinkLost() {
166 noTone(BUZZER_PIN); // Əlaqə kəsildi: səs kəsilir
167}
168
169void setup() {
170 Serial.begin(115200);
171 pinMode(BUZZER_PIN, OUTPUT);
172 btBegin();
173 Serial.print(F("BlueGrays Bluetooth: "));
174 Serial.println(BLE_NAME);
175}
176
177void loop() {
178 btPoll();
179}
180Tez-tez verilən suallar
iPhone ilə işləyir?
Bəli. ESP32-nin daxilindəki Bluetooth Low Energy (BLE) həm iPhone, həm Android ilə işləyir. iPhone HC-05 və HC-06 kimi klassik Bluetooth modullarına qoşula bilmir, bu layihədə onlara ehtiyac da yoxdur. Platanı telefonun Bluetooth ayarlarından cütləşdirməyə çalışma; BLE platalar orada görünməyə bilər, bu normaldır. Əlaqəni BlueGrays tətbiqi qurur.
Aktiv buzzer ilə passiv buzzer arasında fərq nədir, hansı lazımdır?
Bu layihədə passiv buzzer lazımdır. Passiv buzzer kiçik dinamik kimidir: hansı tezliyi göndərsən, həmin notu çalır. Aktiv buzzer-in daxilində öz dövrəsi var, gərginlik alanda həmişə öz sabit səsini çıxarır; onunla klavişləri bir-birindən ayırmaq olmur. Əlindəkinin hansı olduğunu bu layihə ilə başa düşə bilərsən: klavişlər fərqli notlar verirsə passiv, hamısı eyni cızıltılı səs verirsə aktivdir. Alanda məhsulun adında passiv (passive) yazıldığına bax.
Eyni anda iki klavişə basıb akkord çala bilərəm?
Xeyr. Buzzer eyni anda yalnız bir tezlik çala bilər; platadakı tone komandası da hər dəfə tək not yaradır. İki klavişə birlikdə bassan, notlar üst-üstə düşmür, plata yalnız ən son gələn notu çalır. Melodiyaları not-not çal. Paneldəki Tam ekranda çal düyməsi klavişləri böyüdür; orada barmağını klavişlərin üzərində sürüşdürərək notdan nota da keçə bilərsən.
Başqa notlar və ya daha çox klaviş əlavə edə bilərəm?
Paneldəki səkkiz klaviş sabitdir: qalın Do-dan nazik Do-ya, diyez və bemol yoxdur; tətbiqdən klaviş əlavə olunmur. Plata tərəfi isə çevikdir: kod telefondan gələn hər müsbət ədədi tezlik kimi çalır, 0 gələndə susur. Yəni səsi kodda dəyişə bilərsən; məsələn, gələn tezliyi ikiyə vursan, bütün pianino bir oktava nazikləşir.
