ES-101IntermediarIoT

Bandă LED RGB IoT cu ESP32 (WS2812B)

Controlează lumina camerei de pe telefon: alege culoarea, reglează luminozitatea și activează efectul de curcubeu sau de respirație. Ghid pas cu pas pentru șablonul IoT Bandă LED RGB, cu ESP32, o bandă WS2812B cu 30 de LED-uri și trei fire. Mergi la Atelierul meu › Dispozitivele mele › Adaugă un dispozitiv și alege Bandă LED RGB; Ohmi pregătește codul cu cheia dispozitivului tău. Codul de pe pagină este un exemplu: cheia și datele Wi-Fi sunt valori de exemplu.

1.0(1)
3 finalizat
Bandă LED RGB IoT cu ESP32 (WS2812B)
Dacă vrei să lipești o bandă LED în spatele biroului, sub pat sau pe marginea unui raft și să o controlezi de pe telefon, acest proiect este pentru tine. Alegi orice culoare din cercul cromatic al aplicației, reglezi luminozitatea cu un cursor și schimbi atmosfera camerei cu efectul de curcubeu, de respirație sau de clipire. Fiecare LED poate fi controlat separat, astfel încât culorile se deplasează de-a lungul benzii. Aplicația pregătește codul pentru tine; tu doar conectezi trei fire și îl încarci pe placă. Fără tensiune de rețea, doar 5 V.
IoT · control de la distanțăPrimul tău dispozitiv este gratuit

Controlează acest dispozitiv din aplicație

Conectează placa ESP32 sau Raspberry Pi Pico W la Wi-Fi, apoi pornește-o și oprește-o și urmărește măsurătorile live de pe telefon. Codul îl pregătește Ohmi; tu doar introduci datele Wi-Fi și îl încarci.

Șablon în aplicație: Bandă LED RGB

  • Unde găsești în aplicație?Adaugă un dispozitiv nou din fila Unelte sau din Atelier › Dispozitive și alege acest șablon.
  • Bibliotecă ArduinoDeschide Library Manager în Arduino IDE, caută BlueGraysIoT și instalează-l.
Descarcă aplicația gratuit

Planul gratuit include 1 dispozitiv, 1 grafic și 24 de ore de istoric. Cu Premium ai mai multe dispozitive, mai multe grafice și istoric mai lung.

Video

Schemă electrică

Bandă LED RGB IoT cu ESP32 (WS2812B) - Schemă electrică

Cod sursă

C++ (Arduino IDE)
1// ─────────────────────────────────────────
2//   BlueGrays · bluegrays.com
3//   ESP32 IoT RGB LED Strip (WS2812B)
4// ─────────────────────────────────────────
5// The "RGB LED strip" IoT template from the BlueGrays app: change the
6// light, color, brightness and effect (solid, rainbow, breathe, blink, color cycle) of
7// a 30-LED WS2812B strip from your phone. Ohmi prepares the real code in
8// the app with your own device key (Workshop › Devices › Add a device);
9// the code here is an example, the device key and Wi-Fi details are
10// placeholders. Library Manager: BlueGraysIoT (with its dependencies) and
11// Adafruit NeoPixel. The board only joins 2.4 GHz Wi-Fi networks. For 30
12// LEDs at full brightness, power the strip from a separate 5 V 2 A adapter
13// and join the grounds.
14//
15// Pins:
16//   GPIO13 -> WS2812B strip DIN
17//   5V, GND -> Strip 5V, GND
18//   Pico W: strip DIN GP2, 5V VBUS
19
20/*
21 * RGB LED strip · BlueGrays IoT
22 * BlueGrays · bluegrays.com
23 * Do not share this code: it contains your device key and Wi-Fi password.
24 */
25
26#include <BlueGraysIoT.h>
27#include <Adafruit_NeoPixel.h>  // Library Manager: 'Adafruit NeoPixel'
28
29const char *DEVICE_KEY = "YOUR_DEVICE_KEY";
30const char *WIFI_NAME = "YOUR_WIFI_NAME";
31const char *WIFI_PASSWORD = "YOUR_WIFI_PASSWORD";
32
33BlueGraysIoT bg(DEVICE_KEY);
34
35const int LED_COUNT = 30;
36Adafruit_NeoPixel strip(LED_COUNT, 13, NEO_GRB + NEO_KHZ800);
37bool isOn = false; uint8_t cr = 255, cg = 255, cb = 255; int brightness = 70; String effect = "sabit";
38void paint() {
39  strip.setBrightness(isOn ? map(brightness, 0, 100, 0, 255) : 0);
40  for (int i = 0; i < LED_COUNT; i++) strip.setPixelColor(i, strip.gamma32(strip.Color(cr, cg, cb)));  // gamma: the LEDs match the color on screen
41  strip.show();
42}
43
44void setup() {
45  Serial.begin(115200);
46  strip.begin();
47  paint();
48  bg.onSwitch("acik", [](bool on) { isOn = on; paint(); });
49  bg.onColor("renk", [](uint8_t r, uint8_t g, uint8_t b) { cr = r; cg = g; cb = b; paint(); });
50  bg.onNumber("parlaklik", [](float v) { brightness = (int)v; paint(); });
51  bg.onChoice("efekt", [](const char *e) { effect = e; paint(); });
52  bg.setDebug(Serial);
53  bg.setLanguage(BG_LANG_EN);
54  bg.begin(WIFI_NAME, WIFI_PASSWORD);
55}
56
57void loop() {
58  bg.loop();  // avoid long delay() calls here
59  if (isOn && effect == "gokkusagi") {
60    static uint16_t hue = 0; hue += 64;
61    for (int i = 0; i < LED_COUNT; i++) strip.setPixelColor(i, strip.gamma32(strip.ColorHSV(hue + i * 2000)));
62    strip.show(); delay(5);
63  } else if (isOn && effect == "nefes") {  // slowly fades out and in
64    float wave = (sin(millis() / 600.0) + 1.0) / 2.0;
65    strip.setBrightness((uint8_t)(map(brightness, 0, 100, 0, 255) * (0.15 + 0.85 * wave)));
66    strip.show(); delay(10);
67  } else if (isOn && effect == "yanip_sonme") {  // blinks every half second
68    strip.setBrightness((millis() / 500) % 2 ? map(brightness, 0, 100, 0, 255) : 0);
69    strip.show(); delay(10);
70  } else if (isOn && effect == "renk_dongusu") {  // whole strip one color, smooth hue shift
71    static uint16_t hue = 0; hue += 16;
72    uint32_t c = strip.gamma32(strip.ColorHSV(hue));
73    for (int i = 0; i < LED_COUNT; i++) strip.setPixelColor(i, c);
74    strip.show(); delay(10);
75  }
76}
77

Întrebări frecvente

Pot încărca direct pe placă acest cod de pe pagină?

Poți încărca acest cod, dar dispozitivul nu se va conecta: cheia dispozitivului și datele Wi-Fi din cod sunt valori de exemplu. În aplicație, mergi la Atelierul meu › Dispozitivele mele › Adaugă un dispozitiv și alege Bandă LED RGB; Ohmi pregătește codul cu cheia ta, numele rețelei și parola. Copiază acel cod și încarcă-l pe placă. Poți vedea ulterior codul complet în Dispozitiv › Cod și cheie.

Funcționează și cu o placă Pico W?

Da. Alege placa Pico W când adaugi dispozitivul; codul rămâne același, se schimbă doar pinul de date: conectează DIN al benzii la GP2, 5V la VBUS și GND la GND. În Arduino IDE, instalează pachetul "pico" din Boards Manager și biblioteca Adafruit NeoPixel din Library Manager. Circuitul și fotografia de pe această pagină au fost realizate cu o placă ESP32.

Pot alimenta banda prin USB?

Pentru teste scurte, da, dar ai grijă: fiecare LED consumă aproximativ 60 mA când luminează alb la intensitate maximă, așa că 30 de LED-uri pot ajunge la 1,8 A. Acest curent depășește capacitatea USB și a plăcii. Pentru utilizare îndelungată sau la luminozitate mare, alimentează banda de la un adaptor separat de 5 V, 2 A și conectează GND al adaptorului la GND al plăcii. Codul este pentru 30 de LED-uri; dacă banda ta este mai lungă, modifică LED_COUNT și alege un adaptor potrivit.

Ce pot modifica în aplicație?

Ecranul dispozitivului are patru comenzi: comutatorul Lumină aprinde și stinge banda, selectorul Culoare setează aceeași culoare pentru toate LED-urile, cursorul Luminozitate reglează valoarea de la 0 la 100, iar lista Efect oferă opțiunile Constant, Curcubeu, Respirație și Clipire. După o pană de curent, ultimele setări de culoare, luminozitate și efect sunt restabilite imediat ce placa se reconectează.