ES-102IntermediarIoT

Udarea plantelor prin IoT cu ESP32 (senzor de umiditate a solului + pompă)

Pompa pornește automat când pământul din ghiveci se usucă, iar tu urmărești umiditatea pe telefon, în timp real. Acesta este ghidul pas cu pas pentru șablonul IoT Umiditatea solului + pompă din aplicație, cu ESP32, senzor de umiditate a solului, releu și minipompă de apă. Mergi la Atelier › Dispozitive › Adaugă un dispozitiv; Ohmi pregătește codul cu cheia dispozitivului tău. Codul de pe această pagină este un exemplu: cheia și datele Wi-Fi sunt valori de înlocuit.

0.0(0)
Udarea plantelor prin IoT cu ESP32 (senzor de umiditate a solului + pompă)
Dacă vrei ca plantele tale să aibă apă și când pleci în vacanță, acest proiect este pentru tine. Senzorul măsoară umiditatea solului; când aceasta scade sub pragul ales de tine, un releu pornește pompa, apoi o oprește când solul este suficient de umed. Valorile umidității se adună într-un grafic pe telefon, de unde poți schimba pragul sau porni pompa. Pompa este alimentată de propriile baterii, separat de placă, așa că înveți și să ții apa departe de electronică și să faci conexiuni sigure. Notă despre releu: această placă funcționează la 3,3 V. Folosește un modul cu releu și optocuplor, care poate fi comandat cu un semnal de 3,3 V; modulele de 5 V fără optocuplor pot rămâne cuplate la un semnal de 3,3 V.
IoT · control de la distanțăPrimul tău dispozitiv este gratuit

Controlează acest dispozitiv din aplicație

Conectează placa ESP32 sau Raspberry Pi Pico W la Wi-Fi, apoi pornește-o și oprește-o și urmărește măsurătorile live de pe telefon. Codul îl pregătește Ohmi; tu doar introduci datele Wi-Fi și îl încarci.

Șablon în aplicație: Umiditatea solului + pompă

  • Unde găsești în aplicație?Adaugă un dispozitiv nou din fila Unelte sau din Atelier › Dispozitive și alege acest șablon.
  • Bibliotecă ArduinoDeschide Library Manager în Arduino IDE, caută BlueGraysIoT și instalează-l.
Descarcă aplicația gratuit

Planul gratuit include 1 dispozitiv, 1 grafic și 24 de ore de istoric. Cu Premium ai mai multe dispozitive, mai multe grafice și istoric mai lung.

Video

Schemă electrică

Udarea plantelor prin IoT cu ESP32 (senzor de umiditate a solului + pompă) - Schemă electrică

Cod sursă

C++ (Arduino IDE)
1// ─────────────────────────────────────────
2//   BlueGrays · bluegrays.com
3//   ESP32 IoT Plant Watering (Soil Sensor + Pump)
4// ─────────────────────────────────────────
5// The "Soil moisture + pump" IoT template from the BlueGrays app: the soil
6// moisture sensor measures every 2 seconds and sends the value to the app,
7// the relay starts the pump when the moisture drops below the watering
8// threshold and stops it 10 points above it; you can also control the pump
9// and the threshold from your phone. Ohmi prepares the real code in the
10// app with your own device key (Workshop › Devices › Add a device); the
11// code here is an example, the device key and Wi-Fi details are
12// placeholders. Library Manager: BlueGraysIoT (with its dependencies). The
13// board only joins 2.4 GHz Wi-Fi networks. The relay switches on LOW.
14// Safety: power the pump from its own battery holder (4 x AA), not from
15// the board; keep the board, relay and batteries away from water in a
16// closed box; never run the pump dry.
17//
18// Pins:
19//   GPIO34 -> Soil moisture sensor AO
20//   3V3, GND -> Soil moisture sensor VCC, GND
21//   GPIO26 -> Relay module IN
22//   5V, GND -> Relay module VCC, GND
23//   Relay COM -> battery holder (+), NO -> pump (+), pump (-) -> battery holder (-); the pump
24//   runs on its own 4 x AA
25//   Pico W: moisture sensor AO GP26, relay IN GP15
26
27/*
28 * Soil moisture + pump · BlueGrays IoT
29 * BlueGrays · bluegrays.com
30 * Do not share this code: it contains your device key and Wi-Fi password.
31 */
32
33#include <BlueGraysIoT.h>
34
35const char *DEVICE_KEY = "YOUR_DEVICE_KEY";
36const char *WIFI_NAME = "YOUR_WIFI_NAME";
37const char *WIFI_PASSWORD = "YOUR_WIFI_PASSWORD";
38
39BlueGraysIoT bg(DEVICE_KEY);
40
41const int RELAY_PIN = 26;
42const bool RELAY_ACTIVE_LOW = true;  // most relay modules switch on LOW
43void setRelay(bool on) {
44  if (RELAY_ACTIVE_LOW) {
45    if (on) { pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, LOW); }
46    else { pinMode(RELAY_PIN, INPUT); }  // off releases the pin: a 3.3 V HIGH is not enough to turn a 5 V module off
47  } else {
48    pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, on ? HIGH : LOW);
49  }
50}
51const int SOIL_PIN = 34;
52const int SOIL_DRY = 3200;  // reading in dry soil
53const int SOIL_WET = 1300;  // reading in wet soil
54int threshold = 30; bool pump = false; unsigned long lastReadMs = 0;
55
56void setup() {
57  Serial.begin(115200);
58  setRelay(false);
59  analogReadResolution(12);
60  bg.onSwitch("pompa", [](bool on) { pump = on; setRelay(on); });
61  bg.onNumber("esik", [](float v) { threshold = (int)v; });
62  bg.setDeadband("toprak", 1.0);
63  bg.setDebug(Serial);
64  bg.setLanguage(BG_LANG_EN);
65  bg.begin(WIFI_NAME, WIFI_PASSWORD);
66}
67
68void loop() {
69  bg.loop();  // avoid long delay() calls here
70  if (millis() - lastReadMs >= 2000) {
71    lastReadMs = millis();
72    int pct = constrain(map(analogRead(SOIL_PIN), SOIL_DRY, SOIL_WET, 0, 100), 0, 100);
73    bg.send("toprak", pct);
74    // Turn the pump on below the threshold, off 10 points above it
75    if (pct < threshold && !pump) { pump = true; setRelay(true); bg.send("pompa", true); }
76    if (pct > threshold + 10 && pump) { pump = false; setRelay(false); bg.send("pompa", false); }
77  }
78}
79

Întrebări frecvente

Pot încărca direct pe placă codul de pe această pagină?

Îl poți încărca, dar dispozitivul nu se va conecta: cheia dispozitivului și datele Wi-Fi din cod sunt valori de înlocuit. În aplicație, mergi la Atelier › Dispozitive › Adaugă un dispozitiv și alege șablonul Umiditatea solului + pompă; Ohmi pregătește codul cu cheia ta, numele rețelei și parola. Copiază acel cod și încarcă-l pe placă. Poți vedea ulterior codul complet în Dispozitiv › Cod și cheie.

Funcționează și cu Pico W?

Da. Alege placa Pico W când adaugi dispozitivul; codul rămâne același, se schimbă doar pinii și valorile de calibrare: senzorul de umiditate se conectează la GP26 (intrare analogică), iar releul la GP15. În Arduino IDE, instalează pachetul „pico” din Boards Manager. Circuitul și fotografia de pe această pagină au fost realizate cu ESP32.

De ce are pompa propriile baterii?

Curentul consumat de pompă și perturbațiile produse de motorul ei pot reseta placa. De aceea, pompa este alimentată dintr-un suport pentru 4 baterii AA, iar circuitul ei trece doar prin terminalele COM și NO ale releului; nu există o legătură prin fire cu placa. Ține placa, releul și suportul pentru baterii într-o cutie închisă, departe de apă, și păstrează îmbinările firelor uscate. Pompa trebuie să funcționeze doar scufundată în apă; dacă merge fără apă, se încălzește și se defectează în câteva minute. Scoate bateriile când montezi furtunul sau scoți pompa din apă.

Când pornește pompa și ce se întâmplă dacă o comand manual?

Placa măsoară umiditatea la fiecare 2 secunde. Când aceasta scade sub valoarea Prag de udare din aplicație (inițial 30%), pompa pornește și se oprește când umiditatea depășește pragul cu 10 puncte procentuale. Această diferență împiedică pornirile și opririle repetate. Poți acționa și manual comutatorul Pompă, dar regula automată are prioritate: dacă oprești pompa când umiditatea este sub prag, aceasta repornește în cel mult 2 secunde; dacă o pornești când umiditatea este cu 10 puncte procentuale peste prag, se oprește imediat. Reglează pragul în funcție de ghiveciul tău.