ES-15ปานกลาง

วัดอุณหภูมิและความชื้นด้วย ESP32 และ DHT22 (แสดงผลบนจอ LCD)

โปรเจกต์วัดอุณหภูมิและความชื้นโดยรอบด้วยเซ็นเซอร์ DHT22 แล้วแสดงผลแบบเรียลไทม์บนจอ LCD I2C ขนาด 16x2 ใช้ไลบรารี Adafruit DHT อ่านข้อมูลผ่านโพรโทคอลสายเดียว โดย ESP32 สื่อสารกับ DHT22 ผ่านขา GPIO 4 โปรเจกต์นี้เป็นพื้นฐานสำหรับสถานีตรวจอากาศ IoT ระบบบ้านอัจฉริยะ หรือระบบติดตามสภาพแวดล้อมในโรงเรือน

4.8(38)
57 เสร็จแล้ว
วัดอุณหภูมิและความชื้นด้วย ESP32 และ DHT22 (แสดงผลบนจอ LCD)
ถ้าอยากรู้ว่าในห้องร้อนหรือชื้นแค่ไหน เครื่องวัดเล็กๆ นี้เหมาะกับคุณ เซ็นเซอร์ DHT22 วัดอุณหภูมิและความชื้นในอากาศ แล้ว ESP32 จะแสดงค่าบนจอ LCD ด้วยทศนิยม 1 ตำแหน่งทุก 2 วินาที ถ้าอ่านค่าจากเซ็นเซอร์ไม่ได้ หน้าจอก็จะแจ้งให้ทราบด้วย เป็นพื้นฐานสำหรับโปรเจกต์อย่างมุมปลูกต้นไม้หรือสถานีตรวจอากาศในบ้าน

วิดีโอ

แผนผังวงจร

วัดอุณหภูมิและความชื้นด้วย ESP32 และ DHT22 (แสดงผลบนจอ LCD) - แผนผังวงจร

ซอร์สโค้ด

C++ (Arduino IDE)
1// ─────────────────────────────────────────
2//   BlueGrays · bluegrays.com
3//   ESP32 DHT22 Temperature and Humidity (with LCD Display)
4// ─────────────────────────────────────────
5// Reads temperature and humidity from the DHT22 every 2 s and shows them
6// on a 16x2 I2C LCD. If a reading fails, the screen shows a wiring and
7// pull-up warning.
8//
9// Pins:
10//   GPIO 4  -> DHT22 DATA
11//   10k pull-up between DATA and VCC
12//   GPIO 21 -> LCD SDA, GPIO 22 -> LCD SCL
13//   DHT22 VCC -> 3V3, LCD VCC -> 5V (VIN)
14//   All GNDs common
15
16#include <Wire.h>
17#include <LiquidCrystal_I2C.h>
18#include <DHT.h>
19
20// Pin definitions
21const int DHT_PIN = 4;
22#define DHT_TYPE DHT22
23
24DHT dht(DHT_PIN, DHT_TYPE);
25
26// LCD addr 0x27 or 0x3F
27LiquidCrystal_I2C lcd(0x27, 16, 2);
28
29// DHT22 needs at least 2 s between reads
30const unsigned long READ_INTERVAL = 2000;
31unsigned long lastRead = 0;
32
33void setup() {
34  // DevKit V1 default I2C pins
35  Wire.begin(21, 22);
36  lcd.init();
37  lcd.backlight();
38
39  // Splash screen 3 s
40  lcd.setCursor(3, 0);
41  lcd.print("BlueGrays");
42  lcd.setCursor(3, 1);
43  lcd.print("DHT22 v1.0");
44  delay(3000);
45  lcd.clear();
46
47  dht.begin();
48}
49
50void loop() {
51  // Read every 2 s without delay()
52  if (millis() - lastRead >= READ_INTERVAL) {
53    lastRead = millis();
54
55    float h = dht.readHumidity();
56    float t = dht.readTemperature();
57
58    lcd.clear();
59
60    // NaN = wiring/pullup issue
61    if (isnan(h) || isnan(t)) {
62      lcd.setCursor(0, 0);
63      lcd.print("Sensor read fail");
64      lcd.setCursor(0, 1);
65      lcd.print("Wire+10k pullup");
66    } else {
67      // Temperature
68      lcd.setCursor(0, 0);
69      lcd.print("Temp.   :");
70      lcd.print(t, 1);
71      lcd.print("C");
72      // Humidity, DHT22 gives decimals
73      lcd.setCursor(0, 1);
74      lcd.print("Humidity:");
75      lcd.print(h, 1);
76      lcd.print("%");
77    }
78  }
79}
80

FAQ

DHT22 ต่างจาก DHT11 อย่างไร

DHT22 แม่นยำกว่า (อุณหภูมิ ±0.5 °C ความชื้น ±2–5%) วัดได้ในช่วงกว้างกว่า (−40 ถึง 80 °C) และมีความละเอียด 0.1 ส่วน DHT11 ราคาถูกกว่า แต่มีความแม่นยำเพียง ±2 °C และแสดงค่าได้ละเอียดแค่จำนวนเต็ม

ต้องใช้ตัวต้านทาน pull-up 10 kΩ ไหม

เซ็นเซอร์ DHT22 แบบตัวเปล่าต้องใช้ตัวต้านทาน pull-up 10 kΩ ที่สายข้อมูล ส่วนโมดูลแบบ 3 ขาที่ติดตั้งบนบอร์ดมักมีตัวต้านทานนี้อยู่แล้ว

LCD ใช้ 5 V แต่ ESP32 ใช้ 3.3 V ทำงานร่วมกันได้ไหม

โมดูล I2C LCD แสดงภาพได้ชัดกว่าที่ 5 V ถ้าจ่ายไฟให้โมดูลด้วย 5 V และตัวต้านทาน pull-up บนสาย SDA/SCL ต่อกับ 5 V การใช้วงจรแปลงระดับสัญญาณจะปลอดภัยที่สุด แม้หลายคนจะต่อโดยตรง แต่วิธีนั้นทำให้ ESP32 ต้องรับแรงดันเกินขีดจำกัด

ส่งข้อมูลผ่านอินเทอร์เน็ตได้ไหม

ได้ ใช้ Wi-Fi ของ ESP32 ส่งค่าที่วัดได้ไปยัง ThingSpeak หรือ Blynk หรือเซิร์ฟเวอร์ของคุณเอง แล้วดูกราฟบนโทรศัพท์ได้