ES-102ปานกลางIoT

ระบบรดน้ำต้นไม้ IoT ด้วย ESP32 (เซ็นเซอร์ความชื้นในดิน + ปั๊ม)

ให้ปั๊มทำงานเองเมื่อดินในกระถางแห้ง พร้อมดูความชื้นในดินแบบเรียลไทม์ผ่านโทรศัพท์ โปรเจกต์นี้เป็นคู่มือทีละขั้นตอนสำหรับเทมเพลต IoT ความชื้นในดิน + ปั๊มในแอป ใช้ ESP32 เซ็นเซอร์ความชื้นในดิน รีเลย์ และปั๊มน้ำขนาดเล็ก ไปที่คลังของฉัน › อุปกรณ์ของฉัน › เพิ่มอุปกรณ์ Ohmi จะเตรียมโค้ดพร้อมคีย์อุปกรณ์ของคุณ โค้ดในหน้านี้เป็นตัวอย่าง คีย์และข้อมูล Wi-Fi เป็นค่าที่ใส่ไว้ให้แทนที่

0.0(0)
ระบบรดน้ำต้นไม้ IoT ด้วย ESP32 (เซ็นเซอร์ความชื้นในดิน + ปั๊ม)
ถ้าไม่อยากให้ต้นไม้ขาดน้ำระหว่างที่คุณไม่อยู่ โปรเจกต์นี้เหมาะกับคุณ เซ็นเซอร์วัดความชื้นในดิน เมื่อความชื้นต่ำกว่าเกณฑ์ที่ตั้งไว้ รีเลย์จะสั่งให้ปั๊มทำงานและหยุดเมื่อดินชื้นพอ ค่าความชื้นจะบันทึกเป็นกราฟบนโทรศัพท์ คุณยังปรับเกณฑ์หรือสั่งปั๊มจากโทรศัพท์ได้ด้วย ปั๊มใช้ไฟจากแบตเตอรี่แยก ไม่ได้ใช้ไฟจากบอร์ด คุณจึงได้เรียนรู้การแยกน้ำออกจากอุปกรณ์อิเล็กทรอนิกส์และการต่อสายอย่างปลอดภัยด้วย หมายเหตุเกี่ยวกับรีเลย์: บอร์ดนี้ทำงานที่ 3.3 V ให้ใช้โมดูลรีเลย์ที่มีออปโตคัปเปลอร์และสั่งงานด้วยสัญญาณ 3.3 V ได้ โมดูล 5 V ที่ไม่มีออปโตคัปเปลอร์อาจสั่งปิดด้วยสัญญาณ 3.3 V ไม่ได้
IoT · ควบคุมระยะไกลอุปกรณ์แรกใช้ฟรี

ควบคุมอุปกรณ์นี้จากแอป

เชื่อม ESP32 หรือ Raspberry Pi Pico W กับ Wi-Fi แล้วเปิดปิดและดูค่าแบบสดจากมือถือ Ohmi เตรียมโค้ดให้ คุณแค่กรอกข้อมูล Wi-Fi แล้วอัปโหลด

เทมเพลตในแอป: ความชื้นในดิน + ปั๊ม

  • อยู่ตรงไหนในแอปเพิ่มอุปกรณ์ใหม่จากแท็บเครื่องมือ หรือ คลังของฉัน › อุปกรณ์ แล้วเลือกเทมเพลตนี้
  • ไลบรารี Arduinoเปิด Library Manager ใน Arduino IDE ค้นหา BlueGraysIoT แล้วติดตั้ง
ดาวน์โหลดแอปฟรี

แบบฟรีมี 1 อุปกรณ์ 1 กราฟ และข้อมูลย้อนหลัง 24 ชั่วโมง Premium เพิ่มอุปกรณ์ กราฟ และข้อมูลย้อนหลังที่ยาวขึ้น

วิดีโอ

แผนผังวงจร

ระบบรดน้ำต้นไม้ IoT ด้วย ESP32 (เซ็นเซอร์ความชื้นในดิน + ปั๊ม) - แผนผังวงจร

ซอร์สโค้ด

C++ (Arduino IDE)
1// ─────────────────────────────────────────
2//   BlueGrays · bluegrays.com
3//   ESP32 IoT Plant Watering (Soil Sensor + Pump)
4// ─────────────────────────────────────────
5// The "Soil moisture + pump" IoT template from the BlueGrays app: the soil
6// moisture sensor measures every 2 seconds and sends the value to the app,
7// the relay starts the pump when the moisture drops below the watering
8// threshold and stops it 10 points above it; you can also control the pump
9// and the threshold from your phone. Ohmi prepares the real code in the
10// app with your own device key (Workshop › Devices › Add a device); the
11// code here is an example, the device key and Wi-Fi details are
12// placeholders. Library Manager: BlueGraysIoT (with its dependencies). The
13// board only joins 2.4 GHz Wi-Fi networks. The relay switches on LOW.
14// Safety: power the pump from its own battery holder (4 x AA), not from
15// the board; keep the board, relay and batteries away from water in a
16// closed box; never run the pump dry.
17//
18// Pins:
19//   GPIO34 -> Soil moisture sensor AO
20//   3V3, GND -> Soil moisture sensor VCC, GND
21//   GPIO26 -> Relay module IN
22//   5V, GND -> Relay module VCC, GND
23//   Relay COM -> battery holder (+), NO -> pump (+), pump (-) -> battery holder (-); the pump
24//   runs on its own 4 x AA
25//   Pico W: moisture sensor AO GP26, relay IN GP15
26
27/*
28 * Soil moisture + pump · BlueGrays IoT
29 * BlueGrays · bluegrays.com
30 * Do not share this code: it contains your device key and Wi-Fi password.
31 */
32
33#include <BlueGraysIoT.h>
34
35const char *DEVICE_KEY = "YOUR_DEVICE_KEY";
36const char *WIFI_NAME = "YOUR_WIFI_NAME";
37const char *WIFI_PASSWORD = "YOUR_WIFI_PASSWORD";
38
39BlueGraysIoT bg(DEVICE_KEY);
40
41const int RELAY_PIN = 26;
42const bool RELAY_ACTIVE_LOW = true;  // most relay modules switch on LOW
43void setRelay(bool on) {
44  if (RELAY_ACTIVE_LOW) {
45    if (on) { pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, LOW); }
46    else { pinMode(RELAY_PIN, INPUT); }  // off releases the pin: a 3.3 V HIGH is not enough to turn a 5 V module off
47  } else {
48    pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, on ? HIGH : LOW);
49  }
50}
51const int SOIL_PIN = 34;
52const int SOIL_DRY = 3200;  // reading in dry soil
53const int SOIL_WET = 1300;  // reading in wet soil
54int threshold = 30; bool pump = false; unsigned long lastReadMs = 0;
55
56void setup() {
57  Serial.begin(115200);
58  setRelay(false);
59  analogReadResolution(12);
60  bg.onSwitch("pompa", [](bool on) { pump = on; setRelay(on); });
61  bg.onNumber("esik", [](float v) { threshold = (int)v; });
62  bg.setDeadband("toprak", 1.0);
63  bg.setDebug(Serial);
64  bg.setLanguage(BG_LANG_EN);
65  bg.begin(WIFI_NAME, WIFI_PASSWORD);
66}
67
68void loop() {
69  bg.loop();  // avoid long delay() calls here
70  if (millis() - lastReadMs >= 2000) {
71    lastReadMs = millis();
72    int pct = constrain(map(analogRead(SOIL_PIN), SOIL_DRY, SOIL_WET, 0, 100), 0, 100);
73    bg.send("toprak", pct);
74    // Turn the pump on below the threshold, off 10 points above it
75    if (pct < threshold && !pump) { pump = true; setRelay(true); bg.send("pompa", true); }
76    if (pct > threshold + 10 && pump) { pump = false; setRelay(false); bg.send("pompa", false); }
77  }
78}
79

FAQ

อัปโหลดโค้ดในหน้านี้ลงบอร์ดโดยตรงได้ไหม

อัปโหลดได้แต่จะเชื่อมต่อไม่ได้ เพราะคีย์อุปกรณ์และข้อมูล Wi-Fi ในโค้ดเป็นค่าที่ใส่ไว้ให้แทนที่ ในแอปให้ไปที่คลังของฉัน › อุปกรณ์ของฉัน › เพิ่มอุปกรณ์ แล้วเลือกเทมเพลตความชื้นในดิน + ปั๊ม Ohmi จะเตรียมโค้ดพร้อมคีย์ ชื่อเครือข่าย และรหัสผ่านของคุณ คัดลอกโค้ดนั้นแล้วอัปโหลด ภายหลังดูโค้ดทั้งหมดได้ที่อุปกรณ์ › โค้ดและคีย์

ใช้กับ Pico W ได้ไหม

ได้ เลือกบอร์ด Pico W ตอนเพิ่มอุปกรณ์ โค้ดยังเหมือนเดิม เปลี่ยนเฉพาะขาที่ใช้และค่าปรับเทียบ โดยต่อเซ็นเซอร์ความชื้นเข้ากับ GP26 (ขาอินพุตแอนะล็อก) และรีเลย์เข้ากับ GP15 ใน Arduino IDE ให้ติดตั้งแพ็กเกจ "pico" ผ่าน Boards Manager วงจรและภาพในหน้านี้ใช้ ESP32

ทำไมปั๊มต้องใช้แบตเตอรี่แยก

กระแสไฟฟ้าที่ปั๊มดึงไปใช้และสัญญาณรบกวนจากมอเตอร์อาจทำให้บอร์ดรีเซ็ต ปั๊มจึงรับไฟจากรางถ่าน AA 4 ก้อน โดยต่อผ่านเฉพาะขั้ว COM และ NO ของรีเลย์ ไม่มีสายไฟเชื่อมกับบอร์ด เก็บบอร์ด รีเลย์ และรางถ่านไว้ในกล่องปิดให้ห่างจากน้ำ และอย่าให้รอยต่อสายไฟเปียก ปั๊มต้องทำงานขณะอยู่ใต้น้ำเท่านั้น หากเดินปั๊มโดยไม่มีน้ำจะร้อนและเสียภายในไม่กี่นาที ถอดถ่านออกก่อนต่อสายยางหรือยกปั๊มขึ้นจากน้ำ

ปั๊มทำงานเมื่อไร และจะเกิดอะไรขึ้นถ้าสั่งเปิดปิดเอง

บอร์ดวัดความชื้นทุก 2 วินาที เมื่อค่าต่ำกว่าเกณฑ์เริ่มรดน้ำในแอป (ค่าเริ่มต้น 30%) ปั๊มจะเปิด และจะปิดเมื่อความชื้นสูงกว่าเกณฑ์ 10 จุดเปอร์เซ็นต์ ช่วงห่างนี้ช่วยป้องกันปั๊มเปิดปิดถี่ๆ คุณแตะสวิตช์ปั๊มเองได้ แต่กฎอัตโนมัติมีลำดับความสำคัญสูงกว่า หากสั่งปิดขณะความชื้นต่ำกว่าเกณฑ์ ปั๊มจะเปิดอีกภายใน 2 วินาที หากสั่งเปิดขณะความชื้นสูงกว่าเกณฑ์ 10 จุดเปอร์เซ็นต์ ปั๊มจะปิดทันที ปรับเกณฑ์ให้เหมาะกับกระถางของคุณ