ESP32 IoT पौधों को पानी (सॉइल सेंसर + पंप)
गमले की मिट्टी सूखते ही पंप को अपने आप चलने दें, और फ़ोन पर मिट्टी की नमी लाइव देखें। यह प्रोजेक्ट ऐप के मिट्टी की नमी + पंप IoT टेम्पलेट की स्टेप बाय स्टेप गाइड है, जो ESP32, सॉइल मॉइस्चर सेंसर, रिले और मिनी वॉटर पंप से बना है। मेरी वर्कशॉप › मेरे डिवाइस › डिवाइस जोड़ें पर जाएँ; Ohmi आपकी अपनी डिवाइस कुंजी के साथ कोड तैयार करता है। इस पेज का कोड एक उदाहरण है: कुंजी और Wi-Fi की जानकारी नमूना वैल्यू हैं।

इस डिवाइस को ऐप से कंट्रोल करें
अपने ESP32 या Raspberry Pi Pico W को Wi-Fi से जोड़ें, फिर फ़ोन से चालू या बंद करें और लाइव रीडिंग देखें। कोड Ohmi तैयार करता है। आपको बस अपने Wi-Fi की जानकारी डालकर कोड अपलोड करना है।
ऐप में टेम्पलेट: मिट्टी की नमी + पंप
- ऐप में यह कहाँ है?टूल्स टैब या मेरी वर्कशॉप › मेरे डिवाइस से नया डिवाइस जोड़ें और यह टेम्पलेट चुनें।
- Arduino लाइब्रेरीArduino IDE में Library Manager खोलें, BlueGraysIoT खोजें और इंस्टॉल करें।
मुफ़्त प्लान में 1 डिवाइस, 1 चार्ट और 24 घंटे की हिस्ट्री मिलती है। Premium में ज़्यादा डिवाइस, ज़्यादा चार्ट और लंबे समय की हिस्ट्री मिलती है।
वीडियो
सर्किट डायग्राम

सोर्स कोड
1// ─────────────────────────────────────────
2// BlueGrays · bluegrays.com
3// ESP32 IoT Plant Watering (Soil Sensor + Pump)
4// ─────────────────────────────────────────
5// The "Soil moisture + pump" IoT template from the BlueGrays app: the soil
6// moisture sensor measures every 2 seconds and sends the value to the app,
7// the relay starts the pump when the moisture drops below the watering
8// threshold and stops it 10 points above it; you can also control the pump
9// and the threshold from your phone. Ohmi prepares the real code in the
10// app with your own device key (Workshop › Devices › Add a device); the
11// code here is an example, the device key and Wi-Fi details are
12// placeholders. Library Manager: BlueGraysIoT (with its dependencies). The
13// board only joins 2.4 GHz Wi-Fi networks. The relay switches on LOW.
14// Safety: power the pump from its own battery holder (4 x AA), not from
15// the board; keep the board, relay and batteries away from water in a
16// closed box; never run the pump dry.
17//
18// Pins:
19// GPIO34 -> Soil moisture sensor AO
20// 3V3, GND -> Soil moisture sensor VCC, GND
21// GPIO26 -> Relay module IN
22// 5V, GND -> Relay module VCC, GND
23// Relay COM -> battery holder (+), NO -> pump (+), pump (-) -> battery holder (-); the pump
24// runs on its own 4 x AA
25// Pico W: moisture sensor AO GP26, relay IN GP15
26
27/*
28 * Soil moisture + pump · BlueGrays IoT
29 * BlueGrays · bluegrays.com
30 * Do not share this code: it contains your device key and Wi-Fi password.
31 */
32
33#include <BlueGraysIoT.h>
34
35const char *DEVICE_KEY = "YOUR_DEVICE_KEY";
36const char *WIFI_NAME = "YOUR_WIFI_NAME";
37const char *WIFI_PASSWORD = "YOUR_WIFI_PASSWORD";
38
39BlueGraysIoT bg(DEVICE_KEY);
40
41const int RELAY_PIN = 26;
42const bool RELAY_ACTIVE_LOW = true; // most relay modules switch on LOW
43void setRelay(bool on) {
44 if (RELAY_ACTIVE_LOW) {
45 if (on) { pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, LOW); }
46 else { pinMode(RELAY_PIN, INPUT); } // off releases the pin: a 3.3 V HIGH is not enough to turn a 5 V module off
47 } else {
48 pinMode(RELAY_PIN, OUTPUT); digitalWrite(RELAY_PIN, on ? HIGH : LOW);
49 }
50}
51const int SOIL_PIN = 34;
52const int SOIL_DRY = 3200; // reading in dry soil
53const int SOIL_WET = 1300; // reading in wet soil
54int threshold = 30; bool pump = false; unsigned long lastReadMs = 0;
55
56void setup() {
57 Serial.begin(115200);
58 setRelay(false);
59 analogReadResolution(12);
60 bg.onSwitch("pompa", [](bool on) { pump = on; setRelay(on); });
61 bg.onNumber("esik", [](float v) { threshold = (int)v; });
62 bg.setDeadband("toprak", 1.0);
63 bg.setDebug(Serial);
64 bg.setLanguage(BG_LANG_EN);
65 bg.begin(WIFI_NAME, WIFI_PASSWORD);
66}
67
68void loop() {
69 bg.loop(); // avoid long delay() calls here
70 if (millis() - lastReadMs >= 2000) {
71 lastReadMs = millis();
72 int pct = constrain(map(analogRead(SOIL_PIN), SOIL_DRY, SOIL_WET, 0, 100), 0, 100);
73 bg.send("toprak", pct);
74 // Turn the pump on below the threshold, off 10 points above it
75 if (pct < threshold && !pump) { pump = true; setRelay(true); bg.send("pompa", true); }
76 if (pct > threshold + 10 && pump) { pump = false; setRelay(false); bg.send("pompa", false); }
77 }
78}
79FAQ
क्या इस पेज का कोड सीधे अपने बोर्ड पर अपलोड किया जा सकता है?
अपलोड तो हो जाएगा, पर कनेक्ट नहीं होगा: उसमें डिवाइस कुंजी और Wi-Fi की जानकारी नमूना वैल्यू हैं। ऐप में मेरी वर्कशॉप › मेरे डिवाइस › डिवाइस जोड़ें पर जाएँ और मिट्टी की नमी + पंप टेम्पलेट चुनें; Ohmi आपकी कुंजी, नेटवर्क के नाम और पासवर्ड के साथ कोड तैयार करता है। वही कोड कॉपी करके अपलोड करें। पूरा कोड आप बाद में डिवाइस › कोड और कुंजी में भी देख सकते हैं।
क्या यह Pico W के साथ चलता है?
हाँ। डिवाइस जोड़ते समय बोर्ड के रूप में Pico W चुनें; कोड वही रहता है और सिर्फ़ पिन और कैलिब्रेशन वैल्यू बदलती हैं: नमी सेंसर GP26 (एक एनालॉग इनपुट) पर और रिले GP15 पर जाता है। Arduino IDE में Boards Manager से "pico" पैकेज इंस्टॉल करें। इस पेज का सर्किट और फ़ोटो ESP32 से बनाए गए हैं।
पंप की अपनी बैटरियाँ क्यों हैं?
पंप जो करंट खींचता है और उसकी मोटर जो नॉइज़ करती है, वह बोर्ड को रीसेट कर सकती है। इसीलिए पंप 4 x AA बैटरी होल्डर से चलता है और सिर्फ़ रिले के COM और NO टर्मिनल से होकर जाता है; बोर्ड से उसका कोई तार नहीं जुड़ा। बोर्ड, रिले और बैटरी होल्डर को पानी से दूर बंद डिब्बे में रखें, और तारों के जोड़ सूखे रखें। पंप सिर्फ़ पानी के अंदर चलना चाहिए; सूखा चलने पर वह गर्म होकर कुछ ही मिनटों में खराब हो जाता है। पाइप लगाते समय या पंप को पानी से निकालते समय बैटरियाँ निकाल दें।
पंप कब चलता है, और हाथ से चालू-बंद करने पर क्या होता है?
बोर्ड हर 2 सेकंड में नमी मापता है। जब वह ऐप की पानी देने की सीमा (शुरू में 30%) से नीचे जाती है तो पंप चालू होता है, और सीमा से 10 पॉइंट ऊपर बंद होता है; यह अंतर पंप को बार-बार चालू-बंद होने से रोकता है। आप पंप स्विच को हाथ से भी दबा सकते हैं, पर ऑटोमैटिक नियम ही चलता है: मिट्टी सीमा से नीचे रहते आप उसे बंद करें तो वह 2 सेकंड में फिर चालू हो जाता है, और मिट्टी 10 पॉइंट ऊपर रहते चालू करें तो तुरंत बंद हो जाता है। सीमा अपने गमले के हिसाब से सेट करें।
