DC Motor Control with the L298N: Speed and Direction with Arduino

DC motors are the most common motors, spinning fans, robot wheels, water pumps and toy cars. But you can't connect a motor straight to an Arduino pin: it draws far more current than the pin can supply, and changing its direction means reversing its polarity. The L298N motor driver solves both problems at once: it runs two DC motors forwards and backwards independently and sets their speed with PWM. You'll find it in almost every robot car project.

How does a DC motor work, and why does it need a driver?

Apply a voltage across a DC motor's two terminals and it spins; reverse the polarity and it spins the other way; lower the voltage and it slows down. Even a small toy motor draws hundreds of milliamps while running, and more than 1 amp when starting or stalled. And because the motor is a coil, it produces reverse voltage spikes when it switches off. An Arduino pin can supply at most 20–40 mA and isn't protected against those spikes; connecting the motor directly destroys the pin and can even damage the board.

What is an H-bridge?

The way to run a motor in both directions is an H-bridge: four electronic switches arranged around the motor in the shape of the letter "H". When two diagonally opposite switches close, current flows through the motor one way; when the other diagonal pair closes, it flows the other way. The L298N chip contains two such H-bridges, so it can control two motors independently. Each motor uses two direction pins (IN1 and IN2) and one speed pin (ENA):

L298N specifications

L298N pins and power wiring

Running a motor forwards, backwards and at different speeds

First remove the jumper on ENA and connect ENA to Arduino pin D9, IN1 to D8 and IN2 to D7. Connect the motor to OUT1 and OUT2, and a pack of 2 × 18650 cells (7.4 V) or 4–6 AA batteries to the 12V and GND terminals; run GND to the Arduino's GND as well. The motor() function below takes a value from -255 to 255: positive means forwards, negative backwards and zero brake. The idea behind speed control is in What Is PWM?

1const int ENA = 9;    // hız (PWM) / speed (PWM)
2const int IN1 = 8;
3const int IN2 = 7;
4
5void motor(int speed) {              // -255 … 255
6  if (speed == 0) {                  // fren / brake
7    digitalWrite(IN1, HIGH);
8    digitalWrite(IN2, HIGH);
9    analogWrite(ENA, 255);
10    return;
11  }
12  digitalWrite(IN1, speed > 0);      // ileri ya da geri / forward or backward
13  digitalWrite(IN2, speed < 0);
14  analogWrite(ENA, abs(speed));
15}
16
17void setup() {
18  pinMode(ENA, OUTPUT);
19  pinMode(IN1, OUTPUT);
20  pinMode(IN2, OUTPUT);
21}
22
23void loop() {
24  motor(200);   delay(2000);   // ileri / forward
25  motor(0);     delay(500);    // dur / stop
26  motor(-120);  delay(2000);   // yavaşça geri / slowly backward
27  motor(0);     delay(500);
28}

A two-motor robot car: forwards, backwards, left and right

Robot cars have no steering; they turn by spinning the two wheels at different speeds and directions. If both motors run forwards the car goes straight; if the left motor runs backwards and the right one forwards, the car spins left on the spot. The drive() function below takes each motor's speed separately, from -255 to 255:

1// Sol motor / left motor: ENA=9, IN1=8, IN2=7 — Sağ motor / right motor: ENB=10, IN3=5, IN4=4
2const int ENA = 9, IN1 = 8, IN2 = 7;
3const int ENB = 10, IN3 = 5, IN4 = 4;
4
5void drive(int left, int right) {            // her biri -255 … 255 / each -255 … 255
6  digitalWrite(IN1, left >= 0);  digitalWrite(IN2, left < 0);
7  digitalWrite(IN3, right >= 0); digitalWrite(IN4, right < 0);
8  analogWrite(ENA, abs(left));
9  analogWrite(ENB, abs(right));
10}
11
12void setup() {
13  int pins[] = {ENA, IN1, IN2, ENB, IN3, IN4};
14  for (int p : pins) pinMode(p, OUTPUT);
15}
16
17void loop() {
18  drive(200, 200);   delay(1500);   // ileri / forward
19  drive(-200, 200);  delay(600);    // sola dön / turn left
20  drive(200, -200);  delay(600);    // sağa dön / turn right
21  drive(-180, -180); delay(1000);   // geri / backward
22  drive(0, 0);       delay(1000);   // dur / stop
23}

Add a distance sensor to the front of the car and you have a robot that stops and turns when it sees an obstacle; for the sensor side, see HC-SR04 Distance Sensor. If you'll use the Servo library on an Uno, be careful: it disables PWM on pins 9 and 10, so move ENA and ENB to pins 5 and 6.

L298N with the ESP32 and Raspberry Pi Pico

The L298N's inputs treat anything above about 2.3 V as HIGH, so they work directly with the 3.3 V signals of the ESP32 and Pico; the board's logic supply should still be 5 V. On the ESP32 you can use the same Arduino code with PWM-capable pins for ENA and ENB (for example GPIO 25 and 26); pins 34–39 can't output. On the Pico with MicroPython, controlling one motor looks like this:

1from machine import Pin, PWM
2import time
3
4ena = PWM(Pin(15), freq=1000)
5in1 = Pin(14, Pin.OUT)
6in2 = Pin(13, Pin.OUT)
7
8def motor(speed):                   # -100 … 100
9    in1.value(speed > 0)
10    in2.value(speed < 0)
11    ena.duty_u16(int(abs(speed) * 655.35))
12
13while True:
14    motor(80);  time.sleep(2)       # ileri / forward
15    motor(0);   time.sleep(0.5)     # dur / stop
16    motor(-50); time.sleep(2)       # geri / backward

L298N, TB6612FNG or MOSFET?

If you only need to switch a motor on and off, a relay will do, but it can't adjust the speed; we compared the two in What Is a Relay Module? To choose a suitable transistor or MOSFET, have a look at the Transistors tool.

L298N project ideas

• Obstacle-avoiding robot: a car that sees obstacles with an HC-SR04 and changes direction.
• Bluetooth-controlled car: a robot steered over an HC-05 with an app on your phone.
• Joystick-controlled car: turn a joystick's two axes into the speeds of two motors; details in How to Use a Joystick Module.
• Line-following robot: a car that follows a black line on the floor with infrared sensors.
• Automatic curtain: a motorised system that opens the curtain when light arrives in the morning and closes it in the evening.
• Conveyor belt: a small conveyor whose speed you set with a potentiometer.

Common mistakes and how to fix them

• The board's LED is on but the motor doesn't turn: the grounds aren't shared, the ENA jumper was removed but the pin isn't connected, or the PWM value is too low.
• The Arduino resets when the motor runs: the motor and the Arduino share a weak supply; power them separately and solder a 100 nF capacitor across the motor terminals.
• The motor is very slow and weak: the L298N swallows about 2 V; raise the battery voltage (for example 2 × 18650) or use a more efficient driver.
• The motor only turns one way: one of the IN pins isn't connected, or the code writes the same values for both directions.
• The L298N gets very hot: the motor draws too much current; make sure the heatsink is exposed, and choose a beefier driver if needed.
• Using a 9 V PP3 battery: these can't supply high current and run flat quickly; use a rechargeable 18650 or AA pack.

Once you've learned motor control with the L298N, the door to robot projects opens. In the BlueGrays app you'll find L298N Bluetooth-controlled car and obstacle-avoiding robot projects step by step with circuit diagrams and code.