HC-SR04 Distance Sensor: Ultrasonic Distance Measurement with Arduino

The HC-SR04 is a cheap and very common sensor that measures the distance to an object in front of it with sound. It works the way bats find their way: it sends out a high-frequency sound you can't hear and measures how long the echo takes to come back. It's the basis of parking sensors, obstacle-avoiding robots, tank level gauges and height meters.

How does the HC-SR04 work?

1. The Arduino sends a 10-microsecond pulse to the TRIG pin.
2. The sensor emits 8 sound pulses at 40 kHz.
3. The sound bounces off the object and returns; meanwhile the ECHO pin stays HIGH.
4. The Arduino measures how long ECHO stays HIGH and calculates the distance.

Sound travels through air at about 343 m/s, so it covers a centimeter in about 29 microseconds. The measured time covers the trip there and back, so it's divided by two: distance (cm) = time (µs) × 0.0343 / 2, or simply time / 58.

Specifications

Measuring distance with Arduino

Connect VCC to 5V, GND to GND, TRIG to pin 9 and ECHO to pin 10. The code below prints the distance to the serial monitor and reports separately when there's no object or it's too far away.

const int TRIG_PIN = 9;    // tetik / trigger
const int ECHO_PIN = 10;   // yankı / echo

void setup() {
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  Serial.begin(9600);
}

void loop() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);      // 10 µs darbe / 10 µs pulse
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);

  long duration = pulseIn(ECHO_PIN, HIGH, 30000); // en fazla 30 ms bekle / wait max 30 ms
  if (duration == 0) {
    Serial.println("Menzil dışı / out of range");
  } else {
    float cm = duration * 0.0343 / 2;   // gidiş-dönüş / round trip
    Serial.print(cm);
    Serial.println(" cm");
  }
  delay(100);                          // ölçümler arası / between readings
}

Using it with ESP32 and Raspberry Pi Pico

Tips for accurate readings

• Soft and angled surfaces: fabric, foam and angled surfaces don't reflect sound well; readings may be missed.
• Take an average: using the median of 3–5 readings removes sudden jumps.
• Temperature effect: the speed of sound changes by about 0.6 m/s per 1 °C; for precise work, correct it with a temperature sensor.
• Several sensors: sensors triggered at the same time hear each other's echoes; trigger them one after another.
• Measurement interval: leave at least 60 ms between readings so the previous echo dies out.

To combine the sensor with a buzzer for a parking sensor, see What Is a Buzzer?, and to get to know other sensors, read the Arduino Sensors Guide.